GroupBox控件內清除/取消ComboBox控件（一個或多個）

Question

我的問題：

我有一個功能組框之內清除文本框和組合框（DropDownList）。雖然文本框正在清除，但無法清除組合框。

我的代碼：

Public Sub ClearGroupControls() 
    For Each groupboxControl As Control In Me.Controls 
     If TypeOf groupboxControl Is GroupBox Then 
      For Each control As Control In groupboxControl.Controls 
       ' Clear controls 
       If TypeOf control Is TextBox Then 
        control.Text = "" 
       ElseIf TypeOf control Is ComboBox Then 
        'control.Text = String.Empty 
        'control.SelectedIndex = -1 
        control.Text = "" 
       End If 
      Next 
     End If 
    Next 
End Sub 

注：.SelectedIndex = -1產生錯誤：

SelectedIndex is not a member of System.Windows.Forms.Control

...這似乎不一致考慮control.Text工作時控制是一個TextBox。

Answer 1

循環控制集合返回一個沒有SelectedIndex屬性的通用控件。
你需要將其轉換爲適當的類型

Public Sub ClearGroupControls() 
    For Each groupboxControl In Me.Controls.OfType(Of GroupBox)() 
     For Each control As Control In groupboxControl.Controls 
      ' Clear controls 
      If TypeOf control Is TextBox Then 
       control.Text = "" 
      ElseIf TypeOf control Is ComboBox Then 
       Dim cbo = DirectCast(control, ComboBox) 
       cbo.SelectedIndex = -1 
      End If 
     Next 
    Next 
End Sub 

注意的是，在外環你可以使用IEnumerable的擴展需要通過在窗體的Controls集合枚舉返回類型分組框中的只是控制。

您可以在內環改爲兩個循環利用的OfType擴展，但如果真的提供了更好的性能這應該被測量（這在很大程度上取決於當前控件的數量在組框）

Public Sub ClearGroupControls() 
    For Each groupboxControl In Me.Controls.OfType(Of GroupBox)() 
     For Each txt In groupboxControl.Controls.OfType(Of TextBox)() 
      txt.Text = "" 
     Next 
     For Each cbo In groupboxControl.Controls.OfType(Of ComboBox)() 
      cbo.SelectedIndex = -1 
     Next 
    Next 
End Sub