PHP到德爾福和回加密解密使用Rijndael

Question

我有解密使用rijndael密碼從PHP發送到德爾福的字符串的問題。 我在PHP端使用mcrypt，在Delphi端使用DCP_rijndael。

目前我有下面的代碼。

PHP：

function encRJ($key, $iv, $data) 
{ 
    $r = mcrypt_encrypt(MCRYPT_RIJNDAEL_256, $key, $data, MCRYPT_MODE_CBC, $iv); 
    $r = base64_encode($r); 
    return $r; 
} 

而在德爾福：

function decRJ(Data: string; Key: string; IV: string): string; 
var ciph: TDCP_rijndael; 
begin 
    Data := Base64DecodeStr(Data); 

    ciph:= TDCP_rijndael.Create(Self); 
    ciph.Init(Key[1], 256, @IV[1]); 
    ciph.DecryptCBC(Data[1], Data[1], Length(Data)); 
    ciph.Free; 

    Result := Data; 
end; 

我已經利用互聯網實施的密碼在幾個單位審判，發現大多數人都在說關於DCP組件。即便如此，我還沒有設法正確解密。我已經嘗試使用Byte數組作爲參數，AnsiStrings，WideStrings等，但不幸的是沒有運氣。

對不起，如果我在這裏丟失了一些非常明顯的東西，因爲我的思想不夠好，經過幾個小時尋找問題。

Answer 1

您的PHP或您的Delphi方法都不會指定任何填充。如果默認填充不同，那麼你會遇到問題。爲兩者明確指定PKCS7（或PKCS5）。

GregS對解碼Base64結果的評論是正確的。您正在向decRJ（）方法提供加密的密文。這將是隨機出現的字節。試圖將其轉換爲UTF-8將破壞它，因此無法解密。傳入的密文必須從Base64直接轉換爲字節數組。連字符不是字符串，這就是爲什麼它需要轉換爲Base64以作爲文本傳輸。它只會在之後再次被文本解密回明文。

Answer 2

我似乎花了太多時間在這個，但...

您的問題是塊大小。 TDCP_rijndael等同於MCRYPT_RIJNDAEL_128（不是_256）。 ciph.Init（...）調用中的'256'值仍然正確。除此之外，它看起來非常好。也就是說，假設您使用的是鍵/ iv的ansistrings，或者您使用的是非unicode Delphi。
對於unicode的Delphi版本，我傾向於使用TBytes和key [0]/iv [0]。

填充可能仍然是一個問題。如果是這樣，那麼這裏就是我基於PHP手冊頁和一些試驗和錯誤而改變的。

PHP：

function Encrypt($src, $key, $iv) 
{ 
    $block = mcrypt_get_block_size(MCRYPT_RIJNDAEL_128, 'cbc'); 
    //echo "Block size: " . $block . "\r\n"; 
    $pad = $block - (strlen($src) % $block); 
    $src .= str_repeat(chr($pad), $pad); 

    $enc = mcrypt_encrypt(MCRYPT_RIJNDAEL_128, $key, $src, MCRYPT_MODE_CBC, $iv); 
    $r = base64_encode($enc); 
    return $r; 
} 

function Decrypt($src, $key, $iv) 
{ 
    $enc = base64_decode($src); 
    $dec = mcrypt_decrypt(MCRYPT_RIJNDAEL_128, $key, $enc, MCRYPT_MODE_CBC, $iv); 

    $block = mcrypt_get_block_size(MCRYPT_RIJNDAEL_128, 'cbc'); 
    $pad = ord($dec[($len = strlen($dec)) - 1]); 
    return substr($dec, 0, strlen($dec) - $pad); 
} 

德爾福：

function DecryptData(Data: string; AKey: AnsiString; AIv: AnsiString): string; 
var 
    key, iv, src, dest: TBytes; 
    cipher: TDCP_rijndael; 
    slen, pad: integer; 
begin 
    //key := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AKey)); 
    //iv := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AIv)); 
    key := TEncoding.ASCII.GetBytes(AKey); 
    iv := TEncoding.ASCII.GetBytes(AIv); 

    src := Base64DecodeBytes(TEncoding.UTF8.GetBytes(Data)); 

    cipher := TDCP_rijndael.Create(nil); 
    try 
    cipher.CipherMode := cmCBC; 
    slen := Length(src); 
    SetLength(dest, slen); 
    cipher.Init(key[0], 256, @iv[0]); // DCP uses key size in BITS not BYTES 
    cipher.Decrypt(src[0], dest[0], slen); 
    // Remove the padding. Get the numerical value of the last byte and remove 
    // that number of bytes 
    pad := dest[slen - 1]; 
    SetLength(dest, slen - pad); 

    // Base64 encode it 
    result := TEncoding.Default.GetString(dest); 
    finally 
    cipher.Free; 
    end; 
end; 

function EncryptData(Data: string; AKey: AnsiString; AIv: AnsiString): string; 
var 
    cipher: TDCP_rijndael; 
    key, iv, src, dest, b64: TBytes; 
    index, slen, bsize, pad: integer; 
begin 
    //key := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AKey)); 
    //iv := Base64DecodeBytes(TEncoding.UTF8.GetBytes(AIv)); 
    key := TEncoding.ASCII.GetBytes(AKey); 
    iv := TEncoding.ASCII.GetBytes(AIv); 

    src := TEncoding.UTF8.GetBytes(Data); 

    cipher := TDCP_rijndael.Create(nil); 
    try 
    cipher.CipherMode := cmCBC; 
    // Add padding. 
    // Resize the Value array to make it a multiple of the block length. 
    // If it's already an exact multiple then add a full block of padding. 
    slen := Length(src); 
    bsize := (cipher.BlockSize div 8); 
    pad := bsize - (slen mod bsize); 
    Inc(slen, pad); 
    SetLength(src, slen); 
    for index := pad downto 1 do 
    begin 
     src[slen - index] := pad; 
    end; 

    SetLength(dest, slen); 
    cipher.Init(key[0], 256, @iv[0]); // DCP uses key size in BITS not BYTES 
    cipher.Encrypt(src[0], dest[0], slen); 

    b64 := Base64EncodeBytes(dest); 
    result := TEncoding.Default.GetString(b64); 
    finally 
    cipher.Free; 
    end; 
end; 

的PHP和Delphi功能現在給我相同的答案。

編輯

Base64DecodeBytes有點的代碼，我加入到DCP Base64編碼單元：

function Base64DecodeBytes(Input: TBytes): TBytes; 
var 
    ilen, rlen: integer; 
begin 
    ilen := Length(Input); 
    SetLength(result, (ilen div 4) * 3); 
    rlen := Base64Decode(@Input[0], @result[0], ilen); 
    // Adjust the length of the output buffer according to the number of valid 
    // b64 characters 
    SetLength(result, rlen); 
end;