XSLT樣式表：合併的元素爲一個

Question

什麼是XSLT 2.0樣式表，將改變

<paramList> 
    <param name="y" out="true"/> 
    <param name="y" in="true"/> 
    <param name="z" out="true"/> 
    <param name="x" in="true"/> 
</paramList> 

成

<paramList> 
    <param name="x" in="true" /> 
    <param name="y" in="true" out="true"/> 
    <param name="z" out="true"/> 
</paramList> 

在結果中， 「在，只有」 參數之前 「在&出」參數，這反過來又在「僅輸出」參數之前。此外，這兩個「y」元素已合併爲一個。

Answer 1

<?xml version="1.0" ?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="/paramList"> 
    <xsl:copy> 
    <xsl:for-each-group select="param" group-by="@name"> 
     <xsl:sort select="current-group()/@in" order="descending"/> 
     <xsl:sort select="current-group()/@out"/> 
     <param name="{current-grouping-key()}"> 
     <xsl:for-each select="current-group()/@*"> 
      <xsl:copy/> 
     </xsl:for-each> 
     </param> 
    </xsl:for-each-group> 
    </xsl:copy> 
</xsl:template> 

</xsl:stylesheet> 

Answer 2

以防萬一有人需要做的XSLT 1：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:key name="paramsByName" match="param" use="@name"/> 
    <xsl:template match="/paramList"> 
     <xsl:copy> 
      <xsl:for-each select="param[count(. | key('paramsByName', @name)[1]) = 1]"> 
      <xsl:sort select="@name"/> 
      <xsl:copy> 
       <xsl:for-each select="key('paramsByName', @name)"> 
       <xsl:copy-of select="@*"/> 
      </xsl:for-each> 
      </xsl:copy> 
     </xsl:for-each> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

它使用Munchian grouping作爲XSLT 1不具備分組構造。

編輯：

這顯然還可以對進出的屬性只是複製在這種情況下，下面的樣式表不工作（也是繼Dimetre的建議：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:key name="paramsByName" match="param" use="@name"/> 
    <xsl:template match="/paramList"> 
     <xsl:copy> 
      <xsl:for-each select="param[count(. | key('paramsByName', @name)[1]) = 1]"> 
      <xsl:sort select="@name"/> 
      <xsl:copy-of select="key('paramsByName', @name)/@*[local-name() = 'in' or local-name() = 'out']"/> 
     </xsl:for-each> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 3

小改進：

在@ Nick-Jones'和@Obalix的解決方案中，它的編寫較短：

<xsl:copy-of select="current-group()/@*"/> 

分別或

<xsl:copy-of select="key('paramsByName', @name)/@*"/> 

比，：

<xsl:for-each select="current-group()/@*"> 
    <xsl:copy/> 
</xsl:for-each> 

或

<xsl:for-each select="key('paramsByName', @name)">  
<xsl:copy-of select="@*"/>  
</xsl:for-each>  

Answer 4

在輸入文檔中有多個paramList元素的情況下，Obalix的答案可能不起作用。如果文檔描述了一個軟件界面，其中有多個過程，每個過程都有一個paramList，我認爲這可能會使海報感興趣。

下面是一個簡單的輸入：

<root> 
    <func name="one"> 
    <paramList> 
     <param name="y" out="true"/> 
     <param name="y" in="true"/> 
     <param name="z" out="true"/> 
     <param name="x" in="true"/> 
    </paramList> 
    </func> 

    <func name="two"> 
    <paramList> 
     <param name="z" in="true"/> 
    </paramList> 
    </func> 
</root> 

這是我提出的樣式表，建立在Obalix的答案。訣竅是使用包含paramList元素的ID的本地密鑰ID。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:key name="paramsByName" match="param" use="concat(generate-id(..), '/', @name)"/> 
    <xsl:template match="paramList"> 
    <xsl:copy> 
     <xsl:variable name="id" select="generate-id(.)"/> 
     <xsl:for-each select="param[count(. | key('paramsByName', concat($id, '/', @name))[1]) = 1]"> 
     <xsl:copy> 
      <xsl:copy-of select="key('paramsByName', concat($id, '/', @name))/@*"/> 
     </xsl:copy> 
     </xsl:for-each> 
    </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet>