XML定製改造使用XSLT

Question

我有XML輸入，

<?xml version="1.0" encoding="UTF-8"?> 
<Vehicle> 
<Ordinary> 
    <Car>Honda City</Car> 
</Ordinary> 
<Luxury> 
    <Car>Volkswagon</Car> 
</Luxury> 
<Luxury> 
    <Car>Dzire</Car> 
</Luxury> 

我不得不改變使用XSLT到這個XML消息，

<?xml version="1.0" encoding="UTF-8"?> 
<items> 
<item> 
<id>1</id> 
<title>/Vehicle/Ordinary/</title> 
<text>Car</text> 
<answer>Honda City</answer> 
</item> 
<item> 
<id>2</id> 
<title>/Vehicle/Luxury[1]/</title> 
<text>Car</text> 
<answer>Volkswagon</answer> 
</item> 
<item> 
<id>3</id> 
<title>/Vehicle/Luxury[2]/</title> 
<text>Car</text> 
<answer>Dzire</answer> 
</item> 

• 這裏ID可以自動生成唯一編號..
• 所有父標籤Xpath誰沒有任何價值將進入<標題>標籤。
• 有價值的元素進來<文本>標記。
• 實際值進入<答案>標記。
• XSLT應該足夠通用，以適用於給定示例xml不特定的任何格式的XML文檔&。

我已經開始用下面，

<?xml version="1.0" encoding="windows-1252" ?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml"/> 
<xsl:strip-space elements = "*" /> 
<xsl:template match="/"> 
<items> 
<xsl:apply-templates/> 
</items> 
</xsl:template> 
<xsl:template match="text()"> 
<item>  
<title> 
<xsl:for-each select="ancestor-or-self::*"> 
<xsl:text>/</xsl:text> 
<xsl:value-of select="name()" /> 
</xsl:for-each> 
</title>  
<answer> 
<xsl:value-of select="." /> 
<xsl:apply-templates/> 
</answer> 
</item> 
</xsl:template> 
</xsl:stylesheet>  

它產生以下輸出，

<?xml version="1.0" encoding="UTF-8"?> 
<items> 
<item> 
<id>1</id> 
<title>/Vehicle/Ordinary/Car</title> 
<answer>Honda City</answer> 
</item> 
<item> 
<id>2</id> 
<title>/Vehicle/Luxury[1]/Car</title> 
<answer>Volkswagon</answer> 
</item> 
<item> 
<id>2</id> 
<title>/Vehicle/Luxury[2]/Car</title> 
<answer>Dzire</answer> 
</item> 
</items>  

需要你的幫助......

Answer 1

這裏ID可以自動生成唯一編號..

我想用generate-id()來得到一個唯一的ID。

所有的父標籤Xpath誰沒有任何價值將進入 <title>標籤。

根據你的目標輸出，它看起來像你想要的祖先除了第一個。

有價值的元素進入<text>標籤。

只使用父母的name()。

實際值進入<answer>標籤內。

看起來你已經覆蓋了。

實施例...

XSLT 1。0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:strip-space elements= "*"/> 

    <xsl:template match="/"> 
    <items> 
     <xsl:apply-templates/> 
    </items> 
    </xsl:template> 

    <xsl:template match="text()"> 
    <item> 
     <id><xsl:value-of select="generate-id()"/></id> 
     <title> 
     <xsl:for-each select="ancestor::*[position()>1]"> 
      <xsl:value-of select="concat('/',name())"/> 
      <xsl:if test="(preceding-sibling::*| 
      following-sibling::*)[name()=name(current())]"> 
      <xsl:value-of select="concat('[', 
       count(preceding-sibling::*[name()=name(current())])+1, 
       ']')"/> 
      </xsl:if> 
     </xsl:for-each> 
     <xsl:text>/</xsl:text> 
     </title> 
     <text><xsl:value-of select="name(..)"/></text> 
     <answer> 
     <xsl:value-of select="." /> 
     <xsl:apply-templates/> 
     </answer> 
    </item> 
    </xsl:template> 
</xsl:stylesheet> 

輸出

<items> 
    <item> 
     <id>d0t4</id> 
     <title>/Vehicle/Ordinary/</title> 
     <text>Car</text> 
     <answer>Honda City</answer> 
    </item> 
    <item> 
     <id>d0t7</id> 
     <title>/Vehicle/Luxury[1]/</title> 
     <text>Car</text> 
     <answer>Volkswagon</answer> 
    </item> 
    <item> 
     <id>d0t10</id> 
     <title>/Vehicle/Luxury[2]/</title> 
     <text>Car</text> 
     <answer>Dzire</answer> 
    </item> 
</items>