在Inno Setup中獲取字符串的寬度和高度Pascal腳本

Question

是否有我可以在Pascal腳本中獲取字符串的寬度和高度？

例如：

var 
    S: String; 

S := 'ThisIsMyStringToBeChecked' 

在這裏，我需要根據其當前字體大小和字體返回其高度和寬度。

我讀How to get TextWidth of string (without Canvas)?，但無法將其轉換爲Inno Setup Pascal代碼。

我想要這個測量（寬度和高度），以當它的標題的字符串的寬度超過TLabel.Width改變TLabel.Caption等'Too Long To Display'與clRed。

在此先感謝。

Answer 1

的TNewStaticText（不是TLabel）以下工作：

type 
    TSize = record 
    cx, cy: Integer; 
    end; 

function GetTextExtentPoint32(hdc: THandle; s: string; c: Integer; 
    var Size: TSize): Boolean; 
    external 'GetTextExtentPoint32W@Gdi32.dll stdcall'; 
function GetDC(hWnd: THandle): THandle; 
    external 'GetDC@User32.dll stdcall'; 
function SelectObject(hdc: THandle; hgdiobj: THandle): THandle; 
    external 'SelectObject@Gdi32.dll stdcall'; 

procedure SmartSetCaption(L: TNewStaticText; Caption: string); 
var 
    hdc: THandle; 
    Size: TSize; 
    OldFont: THandle; 
begin 
    hdc := GetDC(L.Handle); 
    OldFont := SelectObject(hdc, L.Font.Handle); 
    GetTextExtentPoint32(hdc, Caption, Length(Caption), Size); 
    SelectObject(hdc, OldFont); 

    if Size.cx > L.Width then 
    begin 
    L.Font.Color := clRed; 
    L.Caption := 'Too long to display'; 
    end 
    else 
    begin 
    L.ParentFont := True; 
    L.Caption := Caption; 
    end; 
end;