VBA，用「|」分隔excel文件打開

Question

我有一個宏，可以在excel中打開.txt文件，有沒有辦法在打開時對它們進行分隔？注：多個文件處於打開狀態，所以類似於「|」分隔的活動工作簿，不知道如何分割。 UserInput位於我的字典中，是文件選取器。

這是我目前有：

Sub Rec() 


    Dim wb As Workbook, fileNames As Object, errCheck As Boolean 
    Dim ws As Worksheet, wks As Worksheet, wksSummary As Worksheet 
    Dim y As Range, intRow As Long, i As Integer 



    ' Turn off screen updating and automatic calculation 
    With Application 
     .ScreenUpdating = False 
     .Calculation = xlCalculationManual 
    End With 



'get user input for files to search 
Set fileNames = CreateObject("Scripting.Dictionary") 
errCheck = UserInput.FileDialogDictionary(fileNames) 
If errCheck Then 
    Exit Sub 
End If 


For Each Key In fileNames 'loop through the dictionary 



On Error Resume Next 
Set wb = Workbooks.Open(fileNames(Key)) 
If Err.Number <> 0 Then 
    Set wb = Nothing ' or set a boolean error flag 
End If 
On Error GoTo 0 ' or your custom error handler 


Next 'End of the fileNames loop 
Set fileNames = Nothing 



' Reset system settings 
With Application 
    .Calculation = xlCalculationManual 
    .ScreenUpdating = True 
    .Visible = True 
End With 

End Sub 

任何幫助，將不勝感激。

Answer 1

您使用Excel 2010或更高版本以下應工作（主要變化是你的WorkBooks.Open語句）提供了循環：

Sub Rec() 
    Dim fileNames As Object, errCheck As Boolean 
    Dim ws As Worksheet, wks As Worksheet, wksSummary As Worksheet 
    Dim y As Range, intRow As Long, i As Integer 

    ' Turn off screen updating and automatic calculation 
    With Application 
     .ScreenUpdating = False 
     .Calculation = xlCalculationManual 
    End With 

    'get user input for files to search 
    Set fileNames = CreateObject("Scripting.Dictionary") 
    errCheck = UserInput.FileDialogDictionary(fileNames) 
    If errCheck Then 
     Exit Sub 
    End If 

    For Each Key In fileNames 'loop through the dictionary 

     On Error Resume Next 
     Workbooks.OpenText Filename:=filenames(Key), _ 
          DataType:=xlDelimited, _ 
          Other:=True, _ 
          OtherChar:="|" 
     On Error GoTo 0 ' or your custom error handler 

    Next 'End of the fileNames loop 
    Set fileNames = Nothing 

    ' Reset system settings 
    With Application 
     .Calculation = xlCalculationManual 
     .ScreenUpdating = True 
     .Visible = True 
    End With 
End Sub 

由於如果無法打開文件，Workbooks.OpenText將顯示一條錯誤消息，您可能完全擺脫了您的錯誤處理程序（我在上述編輯版本中已完成此操作），或者可以通過設置Application來禁止OpenText的自動錯誤消息.DisplayAlerts爲False，然後繼續有你自己的錯誤處理程序。 （這取決於如果文件不存在時您想要執行的操作。）

Answer 2

拆分，並通過它

Sub Break_String() 
Dim WrdArray() As String 
Dim text_string As String 
text_string = "A|B|C|D" 
WrdArray() = Split(text_string, "|") 
For i = LBound(WrdArray) To UBound(WrdArray) 
    strg = strg & vbNewLine & "Part No. " & i & " - " & WrdArray(i) 
Next i 
MsgBox strg 
End Sub