如何重新分類Perl對象

Question

我正在使用一些Perl包，我們將其稱爲Some::Parser和Some::Data。 A Some::Parser對象具有返回類型爲Some::Data的對象的方法。我已經寫了一個課程，擴展了Some::Data課程，我們稱之爲My::Data。 My::Data類的對象實際上只是Some::Data類的對象，但使用了更易於使用的其他方法。

我的問題是，我想繼續使用Some::Parser類來解析數據。正如我剛纔所說，Some::Parser對象給我Some::Data對象。一旦我手上有一個Some::Data對象，是否有任何方法將它重新分類爲My::Data對象？我將如何做到這一點？

我完全願意改變我的方法，假設有人可以提出一個更好的方式來做我想做的事情，但是編寫我自己的解析器並不是我想做的事情！

Answer 1

這味道有點像雜碎。現在可能是重新考慮你的戰略的時候了。例如，也許你應該寫My::Parser，它返回My::Data對象。

但是，如果你不想做，你可以手動使用bless改變一個對象的類：

my $obj = Some::Data->new; 
bless $obj, 'My::Data'; 

見的perldoc bless。

Answer 2

你可以重新bless什麼。

在Perl 5中的繼承無非是搜索@ISA。

Answer 3

您可以重新bless返回的對象無論你的心臟的慾望：

#!/usr/bin/perl 

package Some::Data; 
use strict; use warnings; 

sub new { my $class = shift; bless { @_ } => $class } 

sub a { $_[0]->{a} } 

package My::Data; 
use strict; use warnings; 
use base 'Some::Data'; 

sub a_squared { 
    my $self = shift; 
    my $v = $self->a; 
    return $v * $v; 
} 

package Some::Parser; 
use strict; use warnings; 

sub new { my $class = shift; bless { @_ } => $class } 

sub parse { return Some::Data->new(a => 3) } 

package main; 

use strict; use warnings; 

my $data = Some::Parser->new->parse; 
bless $data => 'My::Data'; 

printf "%.1f\t%.1f\n", $data->a, $data->a_squared; 

或者，您可以使用@軍事審判的想法：

#!/usr/bin/perl 

package Some::Data; 
use strict; use warnings; 

sub new { my $class = shift; bless { @_ } => $class } 

sub a { $_[0]->{a} } 

package My::Data; 
use strict; use warnings; 
use base 'Some::Data'; 

sub a_squared { 
    my $self = shift; 
    my $v = $self->a; 
    return $v * $v; 
} 

package Some::Parser; 
use strict; use warnings; 

sub new { my $class = shift; bless { @_ } => $class } 

sub parse { 
    my $self = shift; 
    return $self->data_class->new(a => 3); 
} 

sub data_class { $_[0]->{data_class} } 

package main; 

use strict; use warnings; 

my $data = Some::Parser->new(data_class => 'My::Data')->parse; 
printf "%.1f\t%.1f\n", $data->a, $data->a_squared; 

Answer 4

大概來處理這樣的事情最好的辦法是爲Some::Parser提供一種方法來指定它應該用於數據對象的類。例如，HTML::TreeBuilder提供了element_class方法。如果您希望TreeBuilder生成除HTML::Element節點以外的其他節點，則可以繼承HTML::TreeBuilder並覆蓋element_class以返回所需的節點類。 （TreeBuilder中的實際代碼稍微複雜一點，因爲在HTML-Tree 4之前有一個不同的機制來做這件事，而新的維護者不想破壞它。）

我認爲你沒有寫Some::Parser，但也許它已經具備了這個能力。如果不是，它的維護者可能會接受一個補丁。這應該是一個相當簡單的改變。您只需添加一個data_class方法（sub data_class { 'Some::Data' }），然後將Some::Data->new更改爲$self->data_class->new。然後，您可以子類Some::Parser創建My::Parser，並覆蓋data_class。

Answer 5

我會考慮重新冒險冒險。一旦你有了一個對象，你就無法真正知道它是否是使用它的構造函數創建的（通常是Foo :: new（）），或者某個人重新爲其他對象賦予了它。

的問題是，有些構造函數是脂肪，這意味着他們做一個整體洛塔不僅僅是祝福更多的東西：

sub new { 
    my $pkg = shift; 
    my ($required) = @_; 
    croak "Bad call" unless defined $required; 
    _do_something_magic ($required); 
    my $self = { 'foo' => $required }; 
    return bless $self, $pkg; 
} 

在這種情況下，你再祝福的對象可能不是你所期望的一個後來在代碼中。

人們可能會考慮內置「重新祝福」功能的構造函數。但是這樣的「對象轉換器」會使設計變得更加複雜。

堅持基本定義：「一個對象是類的一個實例。永遠。」。