錯誤＃3002寫入應用程序存儲目錄

Question

所以我試圖將用戶選擇的文件複製到AIR應用程序存儲目錄中，但是當我嘗試解析存儲目錄中的路徑時，我得到：

錯誤＃3002：文件或目錄存在。

即使沒有可能的方式，該文件已經存在（我很確定沒有「qqqqq.txt」那裏）我得到這個。

我的代碼如下所示：

var saveFile:File = File.desktopDirectory; 

saveFile.browseForOpen("Open File");  
saveFile.addEventListener(Event.SELECT, function(e:Event):void 
    { 
      txt.text = saveFile.nativePath; 
      var destination:File = File.applicationStorageDirectory; 
      destination = destination.resolvePath("files/moreInfo.txt"); 
       try 
       { 
       saveFile.copyTo(destination, true); 
       trace("Saved Attachment Success: "+destination.toString()); 
       } 
       catch (error:Error) 
       { trace("Error: "+ error.message); } 
    }); 

錯誤是扔在那裏我嘗試設置目的地爲applicationStorageDirectory線，但我不知道爲什麼。

任何想法？

編輯：所以我評論了一切低於var destination:File = File.applicationStorageDirectory;，它仍然會引發錯誤。

Answer 1

當您調用resolvePath時，將使用resolvePath的返回值 - 它不會將分辨率應用於當前的File對象。

例子：

var prefsFile:File = File.applicationStorageDirectory; 
prefsFile = prefsFile.resolvePath("preferences.xml"); 

而且，看來你的目標文件永遠是：「文件/ moreInfo.txt」

下面是一個示例實現，如果你只是想選擇一個文件被複制到應用程序存儲目錄。

<?xml version="1.0" encoding="utf-8"?> 
<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
         xmlns:s="library://ns.adobe.com/flex/spark" 
         xmlns:mx="library://ns.adobe.com/flex/mx"> 

    <fx:Script> 
     <![CDATA[ 
      /** 
      * Selected file chosen by user. 
      */ 
      protected var sourceFile:File; 


      /** 
      * Function to choose a source file to be copied to 
      * the application storage directory. 
      */ 
      protected function saveButtonClickHandler(event:MouseEvent):void 
      { 
       var fileTypes:FileFilter = new FileFilter("Text File (*.txt)", "*.txt;"); 
       var allTypes:Array = new Array(fileTypes); 

       // default selection to user's desktop 
       sourceFile = File.desktopDirectory; 

       // setup listeners 
       sourceFile.addEventListener(Event.SELECT, fileSelectHandler); 

       // browse for file 
       try 
       { 
        sourceFile.browse(allTypes); 
       } 
       catch (error:Error) 
       { 
        trace("error selecting file to be copied."); 
       } 
      } 

      /** 
      * Called upon selection of file. 
      */ 
      protected function fileSelectHandler(event:Event):void 
      { 
       try 
       { 
        // selected source path 
        trace("Source path: " + sourceFile.nativePath); 

        // set destination path 
        var destinationFile:File = File.applicationStorageDirectory.resolvePath("files/" + sourceFile.name); 
        trace("Destination path: " + destinationFile.nativePath); 

        // check if destination file path already exists and copy 
        if (destinationFile.exists) 
         trace("source file already copied to application storage directory."); 
        else 
         sourceFile.copyTo(destinationFile); 
       } 
       catch (error:Error) 
       { 
        trace("failed to copy source file to destination path."); 
       } 

       // remove listeners 
       sourceFile.removeEventListener(Event.SELECT, fileSelectHandler); 
      } 
     ]]> 
    </fx:Script> 


    <s:Button label="Save As..." 
       click="saveButtonClickHandler(event)" 
       width="100%" 
       height="100%" /> 


</s:WindowedApplication>