Perl - 如何計算和打印電子郵件地址數組中域的出現次數？

Question

我一直在爲此奮鬥了幾天，似乎無法弄清楚。

我有一個通過push(@emails,$email)在一個while循環中創建的電子郵件地址數組。

我正在嘗試創建數組中每個出現計數爲的唯一域的列表。

按發生次數排序。

所以，如果陣列@emails有：

john@yadoo.com ringo@geemail.net george@zoohoo.org paul@yadoo.com

我可以打印：

yadoo.com 2 
geemail.net 1 
zoohoo.org 1 

我發現基於文件中的電子郵件，但，路在我頭上這個例子。有人可以幫助我一個更詳細的代碼示例，可用於一組電子郵件地址？

perl -e 'while(<>){chomp;/^[^@]+@([^@]+)$/;$h{$1}++;} 
foreach $k (sort { $h{$b} <=> $h{$a} } keys %h) {print $h{$k}." ".$k."\n";} infile 

我也試過：（更多我的缺乏理解）

foreach my $domain (sort keys %$domains) { 
    print "$domain"."="; 
    print $domains->{$domain}."\n"; 
}; 

和

my %countdoms; 
$countdoms{$_}++ for @domains; 
print "$_ $countdoms{$_}\n" for keys %countdoms; 

我有很多不同的嘗試最好的結果是總計數（這是1812（準確計數），旁邊有一個數字2，我很接近，可能嗎？

Answer 1

如果你有你的電子郵件地址在一個數組中填充，這會讓你爲每個域計數。我確定有人可以製作更漂亮的東西！

my @emails = ('john@yadoo.com','ringo@geemail.net','george@zoohoo.org','paul@yadoo.com'); 

my %domainCount; 

foreach(@emails){ 
    if ($_ =~ /@(\w+.*)/){ 
     $domainCount{$1}++; 
    } 
} 

for my $domain (sort { $domainCount{$b} <=> $domainCount{$a}} keys %domainCount){ 
    print "$domain - $domainCount{$domain}\n"; 
} 

Answer 2

這是一個有點粗，因爲我是生鏽的Perl的，但這應該做的工作：

use strict; 
$|=1; 
my ($dom, %hsh); 
my @arr = ('john@yadoo.com', 'ringo@geemail.net', 'george@zoohoo.org', 'paul@yadoo.com'); 
foreach (@arr) { 
    ($dom) = ($_ =~ /.*\@(.*)$/); 
    $hsh{$dom}++; 
} 
foreach (keys %hsh) { 
    print ("$_:$hsh{$_}\n"); 
} 

Answer 3

另一個變化：

use strict; 
use warnings; 

my @array 
    = qw<john@yadoo.com ringo@geemail.net george@zoohoo.org paul@yadoo.com> 
    ; 
my %dom_count; 
$dom_count{ $_ }++ foreach map { (split '@')[-1] } @array; 
foreach my $pair ( 
    sort { $b->[1] <=> $a->[1] or $a->[0] cmp $b->[0] } 
    map { [ $_ => $dom_count{ $_ } ] } keys %dom_count 
    ) { 
    print "@$pair\n"; 
} 

Answer 4

而不是給你一個答案，讓我向您解釋您的代碼示例正在做什麼：

while(<>){chomp;/^[^@]+@([^@]+)$/;$h{$1}++;} 
foreach $k (sort { $h{$b} <=> $h{$a} } keys %h) {print $h{$k}." ".$k."\n";} 

第一行從文件中的電子郵件中統計域。

while(<>)逐行重複輸入文件。輸入文件是作爲參數或標準輸入傳遞的文件（如果沒有參數傳遞的話）。每行放置在$_。

chomp;只是從$_末尾刪除換行符。

/^[^@]+@([^@]+)$/是解析出域的正則表達式，適用於$_。它檢查在第一部分沒有'@'的東西，然後是'@'，然後在最後一部分沒有'@'。它記得最後一部分，它將存儲在$1。 ^和$分別代表字符串的開始和結束。

$h{$1}++;使用域（在$1中）來增加散列%h中的計數。這工作即使它不存在，因爲undef行爲很喜歡這裏0

爲了使這項工作對你的列表，你可以做

foreach(@emails) {/^[^@]+@([^@]+)$/;$h{$1}++;} 

第二行顯示出這個哈希%h域。

sort { $h{$b} <=> $h{$a} } keys %h返回按降序排列的域列表，使用比較函數$h{$b} <=> $h{$a}查找計數。請注意，這是b < => a，而不是< => b，這使得它下降。

第2行的其餘部分打印出結果。

HTH。