將兩個XML文件與XSLT結合使用

Question

我需要將兩個XML文件與XSLT合併。他們是這樣的：

<xml xmlns:s='uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882' 
    xmlns:dt='uuid:C2F41010-65B3-11d1-A29F-00AA00C14882' 
xmlns:rs='urn:schemas-microsoft-com:rowset' 
xmlns:z='#RowsetSchema'> 
<s:Schema id='RowsetSchema'> 
    ... Some stuff 
</s:Schema> 
<rs:data> 
    <z:row Initialer='HBL' personaleGrupper='FF' Fornavn='Harald' Efternavn='Blåtand'  personnummer='123459'/> 
</rs:data> 
</xml> 

並與看起來像另一個文件：

<rs:data> 
    <z:row Initialer='KT' personaleGrupper='FF' Fornavn='Kristian' Efternavn='Tyrann' personnummer='546578'/> 
</rs:data> 

我的嘗試是：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:rs="urn:schemas-microsoft-com:rowset" 
      xmlns:z="#RowsetSchema"> 

<xsl:template match="rs:data"> 
<xsl:copy> 
    <xsl:apply-templates select="@* | node() | document('doc2.xml')/rs:data/z:row/node()" /> 
</xsl:copy> 
</xsl:template> 

<xsl:template match="node() | @*"> 
    <xsl:copy-of select="." /> 
</xsl:template> 

</xsl:stylesheet> 

不過，我幾乎得到源代碼的副本文件（doc1.xml）。換句話說，模式部分就在那裏，HaraldBlåtand的一個rs：data行就在那裏。但不是克里斯蒂安Tyrann線。

我在做什麼錯？

Answer 1

我不完全確定你的輸出應該是什麼樣子。

以下xslt將從第一個文檔的rs：data條目後面的doc2.xml複製rs：data條目。

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:rs="urn:schemas-microsoft-com:rowset" 
      xmlns:z="#RowsetSchema"> 

    <xsl:template match="xml"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
      <xsl:apply-templates select="rs:data" mode="copy" /> 
      <xsl:apply-templates select="document('doc2.xml')//rs:data" mode="copy" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="rs:data" /> 

    <xsl:template match="*" mode ="copy"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="node() | @*"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet> 

並生成以下的輸出：

?xml version="1.0"?> 
<xml xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema"> 
    <s:Schema id="RowsetSchema"> 
     ... Some stuff 
    </s:Schema> 

    <rs:data> 
     <z:row Initialer="HBL" personaleGrupper="FF" Fornavn="Harald" Efternavn="Bl&#xE5;tand" personnummer="123459"/> 
    </rs:data> 
    <rs:data> 
     <z:row Initialer="KT" personaleGrupper="FF" Fornavn="Kristian" Efternavn="Tyrann" personnummer="546578"/> 
    </rs:data> 
</xml> 

更新： 似乎應該只有一個RS：數據輸出和僅合併Z：行。試試這個：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
      xmlns:rs="urn:schemas-microsoft-com:rowset" 
      xmlns:z="#RowsetSchema"> 

    <xsl:template match="xml"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="rs:data" > 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
      <xsl:apply-templates select="document('doc2.xml')//rs:data/*" /> 
     </xsl:copy> 
    </xsl:template> 

    <xsl:template match="node() | @*"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node() " /> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

產生：

<xml xmlns:s="uuid:BDC6E3F0-6DA3-11d1-A2A3-00AA00C14882" xmlns:dt="uuid:C2F41010-65B3-11d1-A29F-00AA00C14882" xmlns:rs="urn:schemas-microsoft-com:rowset" xmlns:z="#RowsetSchema"> 
    <s:Schema id="RowsetSchema"> 
     ... Some stuff 
    </s:Schema> 
    <rs:data> 
     <z:row Initialer="HBL" personaleGrupper="FF" Fornavn="Harald" Efternavn="Bl&#xE5;tand" personnummer="123459"/> 
     <z:row Initialer="KT" personaleGrupper="FF" Fornavn="Kristian" Efternavn="Tyrann" personnummer="546578"/> 
    </rs:data> 
</xml>