每X次運行執行批處理文件

Question

我有一個批處理文件，我想在Windows關機時運行（通過GPO關閉腳本執行），但我只希望它在一定數量的系統關閉後運行，而不是在每次關閉時運行。這是因爲它會導致關機過程中的延遲，並希望減少中斷。

我可以考慮的唯一的事情是構建一些邏輯來檢查計算機關閉了多少次，並且在超過定義的閾值後批處理文件被執行，但是誰會有一個例子來說明如何做到這一點？我搜索，但只發現如何運行一個腳本每x個週期或時間，而不是每個x運行的例子。

在此先感謝！

Answer 1

@ECHO OFF 
SET LIMIT=4 
SET SAVEFILE="COUNT.TXT" 
SETLOCAL ENABLEDELAYEDEXPANSION 

REM Get the current count or start a new file if it does not exist. 
IF EXIST %SAVEFILE% GOTO READFILE 
ECHO 0 >%SAVEFILE% 
:READFILE 
SET /P COUNT= <%SAVEFILE% 

REM Increment the save file value by one. 
FOR %%B IN ("%SAVEFILE%") DO (
    CALL :ADD_ONE 
) 
ECHO %COUNT% >%SAVEFILE% 
GOTO CHECK_VALUE 
:ADD_ONE 
SET /A COUNT+=1 
GOTO :EOF 

REM Conditionally reset the counter and do something. 
:CHECK_VALUE 
IF %COUNT% LSS %LIMIT% EXIT /B 
DEL %SAVEFILE% 2>NUL 

ECHO Do your stuff here... 

Answer 2

您可以在每次關機時調用您的批處理文件，並在關閉閾值未滿足時在頂部包含以下內容以中止。

@echo off 

::Test if the shutdown threshold has been met. Exit if it hasn't 
setlocal 
set /a "threshold=5, cnt=1" 
set shutdownCountFile="C:\SomePath\shutdownCount.txt" 
if exist %shutdownCountFile% for /f "usebackq" %%A in (%shutdownCountFile%) do set /a cnt=%%A+1 
if %cnt% geq %threshold% (
    2>nul del %shutdownCountFile% 
    endlocal 
) else (
    >%shutdownCountFile% echo %cnt% 
    exit /b 
) 

:: Your batch process goes here 

您還可以使用註冊表項來跟蹤關閉的數量而不是文件。