使用minOccurs標籤將XSD轉換爲另一個XSD的XSLT

Question

我有一個現有的XSD，其中定義了一系列複雜類型。我需要爲每種類型構建一個相關XSD，但每個複雜類型中的每個元素都需要是可選的（minOccurs =「0」）。

我發現這篇文章是一個例子，從...開始，但我無法添加可選標記。 transforming with xsl an xml schema template to an other xml schema template

任何對XSLT比我更精通的人的幫助？

Answer 1

我沒有測試過很多，因爲您沒有提供樣本，但以下樣式表基於Identity transform可以找到工作。

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema"> 

    <!-- Identity transform - copy everything into output --> 
    <xsl:template match="node() | @*"> 
     <xsl:copy> 
      <xsl:apply-templates select="node() | @*" /> 
     </xsl:copy> 
    </xsl:template> 

    <!-- for not-root xs:element ... --> 
    <xsl:template match="xs:element[ancestor::xs:complexType]"> 
     <xsl:copy> 
      <!-- ... add minOccurs element ...--> 
      <xsl:attribute name="minOccurs">0</xsl:attribute> 
      <!-- ... and copy everything but not minOccurs attribute if any --> 
      <xsl:apply-templates select="node() | @*[not(name() = 'minOccurs')]" />  
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet>