XSL：轉義CDATA並解析爲XML每個內部

Question

我有一個xml文檔（輸入文件無法更改），我需要用xsl轉換爲另一個xml。輸入XSL有CDATA如以下的示例結構：

<TestCaseElement> 
    <Role>VP</Role> 
    <Code> 
     <Line> 
      <![CDATA[<id>l1_SomeId1</id> <val1>l1_SomeVal1</val1> <val2>l1_SomeVal2</val2> <algo>l1_somealgo</algo>]]> 
     </Line> 
     <Line> 
      <![CDATA[<id>l2_someid1</id> <val1>l2_SomeVal1<val1> <val2>l2_SomeVal2<val2> <algo>l2_somealgo</algo>]]> 
     </Line> 
    </Code> 
<TestCaseElement> 

預期的結果是這樣的：

<Expected> 
    <MEASV id="l1_SomeId1" val1="l1_SomeVal1" val2="l1_SomeVal2" algo="l1_somealgo"> 
    <MEASV id="l2_SomeId1" val1="l2_SomeVal1" val2="l2_SomeVal2" algo="l2_somealgo"> 
</Expected> 

我的XSLT是這樣的：

<Expected> 
    <xsl:for-each select="TestCaseElement[(Role='VP')]/Code/Line">      
     <xsl:for-each select="current()/*"> 
      <MEASV> 
       <xsl:attribute name="{fn:local-name()}"><xsl:value-of select="current()"/></xsl:attribute> 
      </MEASV> 
     </xsl:for-each>          
    </xsl:for-each> 
</Expected> 

問題是xslt無法識別CDATA中的標籤。我如何爲每個應用一種禁用輸出轉義？或者任何其他方法來解決這個問題？

Answer 1

考慮使用XSLT 3.0和parse-xml-fragment()（由撒克遜9.8和Altova的XMLSpy的/猛禽提供支援）：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:math="http://www.w3.org/2005/xpath-functions/math" exclude-result-prefixes="xs math" 
    version="3.0"> 

    <xsl:output indent="yes"/> 

    <xsl:template match="/"> 
     <Expected> 
      <xsl:apply-templates select="TestCaseElement[(Role = 'VP')]/Code/Line"/> 
     </Expected> 
    </xsl:template> 

    <xsl:template match="Line"> 
     <MEASV> 
      <xsl:apply-templates select="parse-xml-fragment(.)/*"/> 
     </MEASV> 
    </xsl:template> 

    <xsl:template match="*"> 
     <xsl:attribute name="{local-name()}" select="."/> 
    </xsl:template> 

</xsl:stylesheet> 

請注意，您發佈的樣品中一人逃脫標記<![CDATA[<id>l2_someid1</id> <val1>l2_SomeVal1<val1> <val2>l2_SomeVal2<val2> <algo>l2_somealgo</algo>]]>包含val1和val2不是畸形的標記正確關閉，所以上面的代碼將無法爲輸入或你需要使用try/catch捕獲任何解析錯誤：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:math="http://www.w3.org/2005/xpath-functions/math" 
    xmlns:err="http://www.w3.org/2005/xqt-errors" 
    exclude-result-prefixes="xs math err" 
    version="3.0"> 

    <xsl:output indent="yes"/> 

    <xsl:template match="/"> 
     <Expected> 
      <xsl:apply-templates select="TestCaseElement[(Role = 'VP')]/Code/Line"/> 
     </Expected> 
    </xsl:template> 

    <xsl:template match="Line"> 
     <MEASV> 
      <xsl:try> 
       <xsl:apply-templates select="parse-xml-fragment(.)/*"/> 
       <xsl:catch errors="err:FODC0006"> 
        <xsl:message select="'Error parsing', ."/> 
       </xsl:catch> 
      </xsl:try> 
     </MEASV> 
    </xsl:template> 

    <xsl:template match="*"> 
     <xsl:attribute name="{local-name()}" select="."/> 
    </xsl:template> 

</xsl:stylesheet>