樣式使用XSL的docbook過程的一部分

Question

我試圖影響docbook 5過程中fo：list-block的屬性。我想要做的就是採取以下的DocBook XML代碼：

<procedure> 
    <title>Eating a banana</title> 
    <step><para>Find banana</para></step> 
    <step><para>Peel banana</para></step> 
    <step><para>Stick banana in mouth</para></step> 
<procedure> 

，影響的只是步驟的FO輸出（列表），而不是標題。

使用此：

<xsl:template match="d:procedure"> 
    <fo:block border-left-width="1pt" border-left-style="solid" padding-left="0.25in"> 
     <xsl:apply-imports /> 
    </fo:block> 
</xsl:template> 

獲取我是這樣的：

| 
| Procedure 1: Eating a banana 
| 1. Find banana 
| 2. Peal banana 
| 3. Stick banana in mouth 
| 

我想要得到的是：

Procedure 1: Eating a banana 
    | 1. Find banana 
    | 2. Peal banana 
    | 3. Stick banana in mouth 

試圖匹配<step>無效，因爲docbook將其轉換爲fo：list-block（fo:block作爲的後代生成「無效子女」錯誤）。

Docbook有一個xsl：屬性集<procedures>，但據我所知，只能用於樣式化整個塊（類似於模板match ='d：procedure'，而不僅僅是列表。

Answer 1

這裏是如何可以做到

1. 這個版本的 「程序」 模板（原來是在lists.xsl）添加到您的自定義層：

   <xsl:template match="d:procedure"> 
       <xsl:variable name="id"> 
       <xsl:call-template name="object.id"/> 
       </xsl:variable> 
   
       <!-- Preserve order of PIs and comments --> 
       <xsl:variable name="preamble" 
        select="*[not(self::d:step 
           or self::d:title 
           or self::d:titleabbrev)] 
          |comment()[not(preceding-sibling::d:step)] 
          |processing-instruction()[not(preceding-sibling::d:step)]"/> 
   
       <xsl:variable name="steps" 
          select="d:step 
            |comment()[preceding-sibling::d:step] 
            |processing-instruction()[preceding-sibling::d:step]"/> 
   
       <xsl:call-template name="formal.object.heading"/> 
   
       <fo:block id="{$id}" xsl:use-attribute-sets="procedure.properties list.block.spacing" 
        border-left-width="1pt" border-left-style="solid" padding-left="0.25in"> 
   
       <xsl:apply-templates select="$preamble"/> 
   
       <fo:list-block xsl:use-attribute-sets="list.block.spacing" 
           provisional-distance-between-starts="2em" 
           provisional-label-separation="0.2em"> 
        <xsl:apply-templates select="$steps"/> 
       </fo:list-block> 
   
       </fo:block> 
   </xsl:template> 
   

   <xsl:call-template name="formal.object.heading"/>（它返回fo:block和過程標題）在輸出具有邊框的塊之前執行。我還通過刪除處理標題位置的代碼簡化了模板。

2. 添加文本縮進到formal.title.properties屬性集：

   <xsl:attribute-set name="formal.title.properties" 
          use-attribute-sets="normal.para.spacing"> 
       <xsl:attribute name="text-indent"> 
       <xsl:choose> 
        <xsl:when test="self::d:procedure">-30pt</xsl:when> 
        <xsl:otherwise>0pt</xsl:otherwise> 
       </xsl:choose> 
       </xsl:attribute> 
   </xsl:attribute-set> 
   

這將推動程序標題左側（但先不談其他標題）。

Answer 2

我想出了這個想法。雖然它對於單級過程可以正常工作，但任何帶有子步驟的東西都會導致問題。

<xsl:template match="d:step"> 
    <fo:list-item margin-left="0.25in" padding-left='1em' border-left-width='2pt' border-left-color="gray" border-left-style='solid'> 
     <fo:list-item-label start-indent="0.40in" end-indent="label-end()"> 
      <fo:block> 
       <xsl:number format="1."/> 
      </fo:block> 
     </fo:list-item-label>  
     <fo:list-item-body start-indent="3.5pc"> 
      <fo:block> 
       <xsl:apply-templates /> 
      </fo:block> 
     </fo:list-item-body> 
    </fo:list-item> 
</xsl:template>