如何獲取事務插入的行數

Question

我必須管理一個日誌，我必須查看事務插入的行數。有沒有辦法動態地做到這一點？

Answer 1

@@ ROWCOUNT將給出受上一條 SQL語句影響的行數，最好將它捕獲到有問題的命令後面的局部變量中，因爲下次查看它時它的值會發生變化：

DECLARE @Rows int 
DECLARE @TestTable table (col1 int, col2 int) 
INSERT INTO @TestTable (col1, col2) select 1,2 union select 3,4 
SELECT @Rows=@@ROWCOUNT 
SELECT @Rows AS Rows,@@ROWCOUNT AS [ROWCOUNT] 

OUTPUT：

(2 row(s) affected) 
Rows  ROWCOUNT 
----------- ----------- 
2   1 

(1 row(s) affected) 

你的Rows值2，插入的行數，但ROWCOUNT是1，因爲SELECT @Rows=@@ROWCOUNT命令影響的1行

如果在事務中有多個INSERT或UPDATE等，則需要確定如何「計數」發生了什麼。您可以爲每個表格單獨總計，單個總計值或完全不同的東西。你需要爲每個總要跟蹤並添加到它適用於它的每個操作之後的聲明一個變量：

--note there is no error handling here, as this is a simple example 
DECLARE @AppleTotal int 
DECLARE @PeachTotal int 

SELECT @AppleTotal=0,@PeachTotal=0 

BEGIN TRANSACTION 

INSERT INTO Apple (col1, col2) Select col1,col2 from xyz where ... 
SET @AppleTotal=@AppleTotal+@@ROWCOUNT 

INSERT INTO Apple (col1, col2) Select col1,col2 from abc where ... 
SET @AppleTotal=@AppleTotal+@@ROWCOUNT 

INSERT INTO Peach (col1, col2) Select col1,col2 from xyz where ... 
SET @PeachTotal=@PeachTotal+@@ROWCOUNT 

INSERT INTO Peach (col1, col2) Select col1,col2 from abc where ... 
SET @PeachTotal=@PeachTotal+@@ROWCOUNT 

COMMIT 

SELECT @AppleTotal AS AppleTotal, @PeachTotal AS PeachTotal 

Answer 2

如果你需要爲你的日誌/審計可以輸出條款進一步信息： 這樣，不僅保留了受影響的行數，還記錄了什麼。

作爲插入期間的輸出條款的例子： SQL Server list of insert identities

DECLARE @InsertedIDs table(ID int); 

INSERT INTO YourTable 
    OUTPUT INSERTED.ID 
     INTO @InsertedIDs 
    SELECT ... 

HTH

Answer 3

我找到答案至5月以前的職位。這裏是。

CREATE TABLE #TempTable (id int) 

INSERT INTO @TestTable (col1, col2) OUTPUT INSERTED.id INTO #TempTable select 1,2 

INSERT INTO @TestTable (col1, col2) OUTPUT INSERTED.id INTO #TempTable select 3,4 

SELECT * FROM #TempTable --this select will chage @@ROWCOUNT value