無法設置變量從%%值批處理腳本

Question

從這個 answer我試圖挽救 %%a和 %%b值到變量基於

內，但它不工作：

@ECHO OFF 
SETLOCAL 
set "path_of_folder=C:\folderA\folderB" 

if exist "%path_of_folder%" ( 
    echo Path exists. 
    for /f "skip=5 tokens=1,2,4 delims= " %%a in (
    'dir /ad /tc "%path_of_folder%\."') do IF "%%c"=="." (
    set "dt=%%a" 
    echo Created on: %%a, %%b 
    set "vara=%%a" 
    set "varb=%%b" 
    echo %vara%, %varb% 

    REM substring 
    set day=%vara:~0,2% 
) 
) else ( 
    echo Path does not exist. 
) 

GOTO :EOF 

但echo %vara%, %varb%的輸出爲空即使之前echo Created on: %%a, %%b打印正確的信息！這個想法是，我可以在之後操作該變量，例如提取子字符串。

在網上搜索後，我發現這個answer從中我嘗試了setlocal ENABLEDELAYEDEXPANSION，並用驚歎號的方法，但他們也失敗了。

[更新，包括我的其他的嘗試和使用感嘆號時，部分修復]

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
set "path_of_folder=C:\folderA\folderB" 

if exist "%path_of_folder%" ( 
    echo Path exists. 
    for /f "skip=5 tokens=1,2,4 delims= " %%a in (
    'dir /ad /tc "%path_of_folder%\."') do IF "%%c"=="." (
    set "dt=%%a" 
    echo Created on: %%a, %%b 
    set vara=%%a 
    set varb=%%b 
    echo !vara!, !varb! 

    REM substring 
    set day=%vara:~0,2% 
) 
) else ( 
    echo Path does not exist. 
) 

GOTO :EOF 

凡vara和varb現在被保存並適當地迴應，但現在子不工作..

我嘗試閱讀更多關於%%變量（link）的具體信息，但這對我也沒有幫助。

任何建議/例如please？

Answer 1

你的第二個腳本完美地工作。我可以發現的唯一錯誤是在這一行：set day=%vara:~0,2%。它應該是set day=!vara:~0,2!。

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
set "path_of_folder=C:\folderA\folderB" 

if exist "%path_of_folder%" ( 
    echo Path exists. 
    for /f "skip=5 tokens=1,2,4 delims= " %%a in (
    'dir /ad /tc "%path_of_folder%\."') do IF "%%c"=="." (
    set "dt=%%a" 
    echo Created on: %%a, %%b 
    set vara=%%a 
    set varb=%%b 
    echo !vara!, !varb! 

    REM substring 
    set day=!vara:~0,2! 
) 
) else ( 
    echo Path does not exist. 
)