分割範圍包含多個範圍到一個範圍數組中？

Question

我試圖將多個範圍選擇轉換爲範圍數組。

眼下這就是我想：

Private Function SplitRange(ByRef r As Range) As Range() 
    Dim i As Long 
    Dim RangesArray() As Range 
    Dim AddressArray() As String 
    Dim Address As Variant 
    i = 0 
    AddressArray = Split(r.Address, ",") 
    ReDim RangesArray(UBound(AddressArray)) 
    For Each Address In AddressArray 
     Set RangesArray(i) = Range(Address) 
     i = i + 1 
    Next Address 
    ' It works till this point, executing RangesArray(0).Address returns a range address 
    SplitRange = RangesArray 
    ' Here for some reason neither SplitRange(0).Address or RangesArray(0).Address work 
End Function 

我如何轉換的「複合型」的範圍爲範圍的數組？

Answer 1

Range類型的每個對象都有屬性Areas，其中包含其子範圍的集合。您可以對此集合中的項目進行操作，而不是創建數組。

但如果你真的需要一個數組，你可以很容易地將它轉換這樣的：

Public Function SplitRange(ByRef r As Range) As Range() 
    Dim i As Long 
    Dim ranges() As Range 
    Dim subrange As Range 
    '---------------------------------------------------------------- 

    ReDim ranges(0 To r.Areas.Count - 1) 
    For Each subrange In r.Areas 
     Set ranges(i) = subrange 
     i = i + 1 
    Next subrange 

    SplitRange = ranges 

End Function