如何將Windows媒體鍵分配給Visual Basic中的函數

Question

我在Visual Studio 2010中用Visual Basic創建了音樂播放器。現在我想將右上角的按鍵分配給一個函數。至少在我的鍵盤上，'Home'，'Pg Up'，'Pg Down'和'End'鍵都有媒體鍵（暫停/播放，停止，上一個，前進）。這些都是用藍色寫的，所以顯然你需要按'Fn'來使用替代功能（而不是'Home'，按'Fn'+'Home'）。可能不是最清楚的解釋，但它不完全是火箭科學來理解我想要做什麼。我想在用戶按住'Fn'並按下上面提到的其中一個按鈕時啓動一個功能。

在此先感謝

Answer 1

您可以捕獲使用Keys.MediaXXX常數的多媒體鍵。下面是一個標準的形式捕獲這些鍵的例子：

Public Class Form1 

    Protected Overrides Function ProcessKeyMessage(ByRef m As System.Windows.Forms.Message) As Boolean 
     Const WM_KEYDOWN As Integer = &H100 
     If m.Msg = WM_KEYDOWN Then 
      Select Case m.WParam.ToInt32 
       Case Keys.MediaStop 
        Debug.Print("Stop") 
       Case Keys.MediaPlayPause 
        Debug.Print("PlayPause") 
       Case Keys.MediaNextTrack 
        Debug.Print("Next") 
       Case Keys.MediaPreviousTrack 
        Debug.Print("Previous") 
      End Select 
     End If 
     Return MyBase.ProcessKeyMessage(m) 
    End Function 

End Class 

*這也可以在表格的KeyDown（）事件中使用e.KeyData中完成的。

編輯：這裏是使用窗體的KeyDown（）事件的一個例子。請注意，我啓用了KeyPreview（）;如果窗體上有任何控件可以獲得焦點，則需要執行此操作：

Public Class Form1 

    Private Sub Form1_Load(sender As System.Object, e As System.EventArgs) Handles MyBase.Load 
     Me.KeyPreview = True 
    End Sub 

    Private Sub Form1_KeyDown(sender As Object, e As System.Windows.Forms.KeyEventArgs) Handles Me.KeyDown 
     Select Case e.KeyData 
      Case Keys.MediaStop 
       Debug.Print("Stop") 
      Case Keys.MediaPlayPause 
       Debug.Print("PlayPause") 
      Case Keys.MediaNextTrack 
       Debug.Print("Next") 
      Case Keys.MediaPreviousTrack 
       Debug.Print("Previous") 
     End Select 
    End Sub 

End Class