如何在新實例中打開PowerPoint後端工作表

Question

我正在使用vba更新PowerPoint演示文稿。 ppt中有30個圖表，我將把一些excel表格中的數據應用到powerpoint圖表的後端excel表格中。但每次我這樣做時，我都可以看到新的Excel表單在任務欄中打開。即使他們沒有在整個屏幕上顯示

Set CExcel = New Excel.Application 
CExcel.Visible = False 
Set CWB2 = CExcel.Workbooks.Open(PPPres.Slides(lngSldNo).Shape(strChartName).Chart.ChartData.Workbook) 

這是我使用的代碼，但它給我的錯誤，你不能打開一個文件，這樣 你能告訴我怎麼後端表的簡報圖表可以在一個新實例，而不顯示文件和其標籤也

感謝事先被打開

Answer 1

的第一參數來Workbooks.Open方法是包含文件路徑的字符串，例如

Sub Test() 
Dim EAPP As Excel.Application, EWB As Excel.Workbook 

    Set EAPP = New Excel.Application 
    Set EWB = EAPP.Workbooks.Open("C:\Users\Myself\Desktop\MyFile.xlsx") 

    Set EWB = Nothing 
    Set EAPP = Nothing 
End Sub 

不確定這是由您的論點交付。 Application.Visible屬性默認爲False，所以不需要明確設置它。我猜你已經創建了一個Excel對象庫的引用，以便使用Powerpoint中的Excel對象進行早期綁定。

Answer 2

邏輯：

1. 獲取其具有Chart對象形狀
2. 獲取您的Chart對象，然後獲取Chartdata
3. 啓動圖表，並設置工作簿和您的Excel應用對象

假設：

出於演示的目的，我假定以下

1. 在演示Slide1具有一個形狀，其是一個圖表
2. 我已經加入這兩種方案。即Automating Excel from PowerPoint和Automating PowerPoint from Excel

這是你正在嘗試的嗎？從PowerPoint

Option Explicit 

Sub Sample() 
    '~~> Excel Objects 
    Dim oXlApp As Object, oXlWb As Object, oXlSheet As Object 
    '~~~> Powerpoint objects 
    Dim oPPChart As Chart 
    Dim oPPChartData As ChartData 

    '~~> Working with shape1 
    With ActivePresentation.Slides(1).Shapes(1) 
     If .HasChart Then 
      Set oPPChart = .Chart 
      Set oPPChartData = oPPChart.ChartData 

      oPPChartData.Activate 

      '~~> Set your Excel objects here 
      Set oXlWb = oPPChartData.Workbook 
      Set oXlApp = oXlWb.Parent 

      oXlApp.Visible = False 

      Debug.Print oXlApp.Name 
      Debug.Print oXlWb.Name 


      ' 
      '~~> Rest of your code 
      '  
     End If 
    End With 

    '~~> Close And Cleanup 
    oXlWb.Close False 
    oXlApp.Quit 

    Set oXlSheet = Nothing 
    Set oXlWb = Nothing 
    Set oXlApp = Nothing 
End Sub 

CODE自動化Excel：

代碼的PowerPoint自動化從Excel

Option Explicit 

Sub Sample() 
    '~~> Excel Objects 
    Dim oXlApp As Application, oXlWb As Workbook, oXlSheet As Worksheet 

    '~~~> Powerpoint objects 
    Dim oPPApp As Object, oPPprsn As Object, oPPSlide As Object 
    Dim oPPChart As Object, oPPChartData As Object 

    Application.ScreenUpdating = False 

    '~~> Establish a Popwerpoint application object 
    On Error Resume Next 
    Set oPPApp = GetObject(, "PowerPoint.Application") 

    '~~> If not found then create new instance 
    If Err.Number <> 0 Then 
     Set oPPApp = CreateObject("PowerPoint.Application") 
    End If 
    Err.Clear 
    On Error GoTo 0 

    '~~> open relevant powerpoint file 
    Set oPPprsn = oPPApp.Presentations.Open("C:\Presentation1.pptx") 
    Set oPPSlide = oPPprsn.Slides(1) 

    '~~> Working with shape1 
    With oPPSlide.Shapes(1) 
     If .HasChart Then 
      Set oPPChart = .Chart 
      Set oPPChartData = oPPChart.ChartData 

      oPPChartData.Activate 

      '~~> Set your Excel objects here 
      Set oXlWb = oPPChartData.Workbook 
      Set oXlApp = oXlWb.Parent 

      '~~> This is required if powerpoint chartdata 
      '~~> opens in the same instance of this excel 
      oXlWb.Windows(1).Visible = False 
      'oXlApp.Visible = False 

      Debug.Print oXlApp.Name 
      Debug.Print oXlWb.Name 

      ' 
      '~~> Rest of your code 
      ' 
     End If 
    End With 

    oXlWb.Windows(1).Visible = True 

    '~~> Close And Cleanup 
    oXlWb.Close False 

    oPPprsn.Close 
    oPPApp.Quit 

    Application.ScreenUpdating = True 

    Set oPPChartData = Nothing 
    Set oPPChart = Nothing 
    Set oPPChartData = Nothing 
    Set oPPSlide = Nothing 
    Set oPPprsn = Nothing 
    Set oPPApp = Nothing 
End Sub