如何給頁面編組？

Question

這是關於通過使用索引文件訪問單個XML文件的多個分組XML文件的頁碼編號。編號必須爲每個組重新開始，並跨越組中的所有文件。這是我的index.xml文件，定義了團體和個人文件：

<list> 
    <numberGroup> 
    <entry> 
     <file>n1.xml</file> 
    </entry> 
    <entry> 
     <file>n2.xml</file> 
    </entry> 
    <entry> 
     <file>n3.xml</file> 
    </entry> 
    </numberGroup> 
    <numberGroup> 
    <entry> 
     <file>p1.xml</file> 
    </entry> 
    <entry> 
     <file>p2.xml</file> 
    </entry> 
    <entry> 
     <file>p3.xml</file> 
    </entry> 
    </numberGroup> 
    <numberGroup> 
    <entry> 
     <file>a1.xml</file> 
    </entry> 
    <entry> 
     <file>a3.xml</file> 
    </entry> 
    </numberGroup> 
</list> 

所有<file>小號n1.xml，n2.xml等有衆多的標籤<page/>，即在轉換過程轉化爲頁碼。 （<span class="r" id="pg12">...</span>）

這是模板我到目前爲止：

<xsl:template match="page"> 
<xsl:variable name="vRoot" select="generate-id(/)"/> 
<xsl:variable name="vPage" select="$vFiles[$vRoot = generate-id(document(.))]"/> 
<span class="r"> 
    <xsl:attribute name="id">pg<xsl:value-of select="count(document((.|$vPage)/preceding::file)//page | (.|$vPage)/preceding::page) + 1"> 
    </xsl:value-of></xsl:attribute> 
     ... 
</span> 
</xsl:template> 

的問題是，該編號不爲1重啓每個新numberGroup。

有什麼建議嗎？

Answer 1

您正在考慮考慮所有page元素的完整節點集的元素。如果您想重新啓動每個numberGroup中的編號，您必須在此上下文中選擇它們。

我假設你n1.xml，p1.xml文件有以下格式：

<pages> 
    <page/> 
    <page/> 
    <page/> 
</pages> 

您可以限制選擇的背景下，這是每個numberGroup通過創建numberGroup模板，選擇page文件該範圍內的元素：現在

<xsl:template match="numberGroup"> 
    <xsl:apply-templates select="document(entry/file)//page"/> 
</xsl:template> 

，爲每個頁面，你只需要得到它的position()：

<xsl:template match="page"> 
    <span class="r" id="pg{position()}"/> 
</xsl:template> 

這會產生這樣的結果：

<div> 
    <span class="r" id="pg1"/> 
    <span class="r" id="pg2"/> 
    ... 
    <span class="r" id="pg99"/> <!-- total pages of all files in the first group --> 
</div> 
<div> 
    <span class="r" id="pg1"/> 
    <span class="r" id="pg2"/> 
    ... 
    <span class="r" id="pg19"/> <!-- total pages in second group --> 
</div> 
<div>...</div> 

因此，解決辦法應該是比你想的簡單得多。您不需要任何變量或複雜的XPath表達式。下面是應該產生一個結果的完整樣式類似於你所期望的：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output indent="yes"/> 
    <xsl:strip-space elements="*"/> 

    <xsl:template match="numberGroup"> 
     <div> 
      <xsl:apply-templates select="document(entry/file)//page"/> 
     </div> 
    </xsl:template> 

    <xsl:template match="page"> 
     <span class="r" id="pg{position()}"/> 
    </xsl:template> 
</xsl:stylesheet>