GNU鏈接器ARM - 爲什麼我的部分重疊？

Question

我需要添加一個小堆以使用TM4C ARM微控制器上的標準庫函數（_sbrk需要end符號）。

這是我的鏈接腳本（附帶微控制器演示）：

/* Entry Point */ 
ENTRY(Reset_Handler) 

HEAP_SIZE = 1024; 

MEMORY 
{ 
    FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 0x00100000 
    SRAM (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00040000 
} 

SECTIONS 
{ 
    .text : 
    { 
     _text = .; 
     KEEP(*(.isr_vector)) 
     *(.text*) 
     *(.rodata*) 
     _etext = .; 
    } > FLASH 

    .data : AT(ADDR(.text) + SIZEOF(.text)) 
    { 
     _data = .; 
     _ldata = LOADADDR (.data); 
     *(vtable) 
     *(.data*) 
     _edata = .; 
    } > SRAM 

    .bss : 
    { 
     _bss = .; 
     *(.bss*) 
     *(COMMON) 
     _ebss = .; 
    } > SRAM 

    .heap : AT(ADDR(.bss) + SIZEOF(.bss)) 
    { 
     . = ALIGN(8); 
     __end__ = .; 
     PROVIDE(end = .); 
     __HeapBase = .; 
     . += HEAP_SIZE; 
     __HeapLimit = .; 
    } > SRAM 
} 

我只加.HEAP後的.bss類推到。數據/的.text，但我得到的鏈接錯誤：

ld: section .init loaded at [000126b4,000126bf] overlaps section .data loaded at [000126b4,00012f8f] 
collect2: error: ld returned 1 exit status 

這也發生在我刪除AT(ADDR(.bss) + SIZEOF(.bss))時。當我刪除.heap並調用libc函數編譯和鏈接時，輸出二進制文件正確運行。

如何調整腳本以正確放置堆後bss？

Answer 1

事實證明，我的堆和bss是正確的，但是當鏈接標準庫函數時，添加了名爲.init和.fini的新節 - 它們與.data相沖突。這是我糾正鏈接腳本：

/* Entry Point */ 
ENTRY(Reset_Handler) 

HEAP_SIZE = 1024; 

MEMORY 
{ 
    FLASH (rx) : ORIGIN = 0x00000000, LENGTH = 0x00100000 
    SRAM (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00040000 
} 

SECTIONS 
{ 
    .text : 
    { 
     _text = .; 
     KEEP(*(.isr_vector)) 
     *(.text*) 
     *(.rodata*) 
     KEEP (*(.init)) 
     KEEP (*(.fini)) 
     _etext = .; 
    } > FLASH 

    .ARM.extab : 
    { 
     *(.ARM.extab* .gnu.linkonce.armextab.*) 
    } > FLASH 

    .ARM : 
    { 
     __exidx_start = .; 
     *(.ARM.exidx*) 
     __exidx_end = .; 
    } > FLASH 

    __end_code = .; 

    .data : AT(__end_code) 
    { 
     _data = .; 
     _ldata = LOADADDR (.data); 
     *(vtable) 
     *(.data*) 
     _edata = .; 
    } > SRAM 

    .bss : 
    { 
     _bss = .; 
     *(.bss*) 
     *(COMMON) 
     _ebss = .; 
    } > SRAM 

    .heap : AT(_ebss) 
    { 
     . = ALIGN(8); 
     __end__ = .; 
     PROVIDE(end = .); 
     __HeapBase = .; 
     . += HEAP_SIZE; 
     __HeapLimit = .; 
    } > SRAM 
} 

我添加的行KEEP (*(.init))，KEEP (*(.fini))和.ARM段（從另一個MCU連接腳本）。現在一切鏈接和運行良好。