如何使用PERL腳本過濾掉XML中的節點

Question

這個問題遍佈互聯網，但我看到的所有示例都沒有考慮到我顯然獨特的情況。這裏是我的XML摘錄：

<message type="error" from="Realtime" timestamp="Mon Nov 24 19:28:55 2014"> Could not receive from Loader </message> 
<message type="warning" from="Dcd_Mux" timestamp="Mon Dec 1 02:31:18 2014"> Could not connect to Dcd </message> 

而不是有幾個層次的節點，我只是在消息節點上有幾個屬性。我希望能夠根據我的Perl腳本的參數過濾掉節點。例如：如果我想過濾掉type =「error」的所有消息，並且我使用的是隻包含上面兩行的XML，那麼我的輸出將只是上面的警告消息。這裏顯示輸出：

<message type="warning" from="Dcd_Mux" timestamp="Mon Dec 1 02:31:18 2014"> Could not connect to Dcd </message> 

我需要如何開始打開XML，通過整個事情循環，並刪除具有符合我的篩選器屬性的任何節點的一些方向。我有興趣使用LibXML來完成這件事。

Answer 1

我使用XML::LibXML作爲我的XML解析器。

use XML::LibXML qw(); 

die "usage\n" if @ARGV != 2; 

my ($type, $qfn) = @ARGV; 
my $doc = XML::LibXML->new->parse_file($qfn); 
for my $node ($doc->findnodes('//message') { 
    my $type_addr = $node->getAttribute('type'); 
    next if !$type_addr || $type_addr ne $type; 

    $node->parentNode->removeChild($node); 
} 

$doc->toFile($qfn); 

Answer 2

它可以使用XML::LibXML是這個樣子：

use strict; 
use warnings; 

use XML::LibXML; 

my $filename = $ARGV[0] 
    or die "Missing XML filename to parse"; 
my $type = $ARGV[1] 
    or die "Missing type of node to exclude"; 

open(my $xml_file, '<', $filename) 
    or die "Cannot open XML file '$filename' for reading: $!"; 

my $dom = XML::LibXML->load_xml(IO => $xml_file); 
NODE: 
foreach my $message_node ($dom->findnodes('/root/message')) { 
    next NODE 
     unless $message_node->hasAttribute('type'); 

    $message_node->unbindNode() 
     if $message_node->getAttribute('type') eq $type; 
} 
$dom->toFile($filename); 

Answer 3

有兩個元素，您的問題 - 先建立一個篩選條件，選擇或基於它刪除元素。

特別是 - 混合'添加'和'刪除'可能是相當困難的，因爲決定如果不適用或相互矛盾會怎麼做可能會很煩人。

無論如何，我提供XML::Twig，儘管這不是您要求的 - 因爲我已經使用了它，並沒有真正觸及LibXML。

#!/usr/bin/perl 
use strict; 
use warnings; 

use XML::Twig; 

#read these from ARGV, just here as example. 
my @sample_filters = qw (-type=error 
          -from=Not_Dcd_Mux); 

my %exclude; 
for (@sample_filters) { 
    if (m/^-/) { 
     my ($att, $criteria) = (
      m/^-  #starts with - 
       (\w+) #word 
       =  
       (\w+) 
       $  #end of string 
       /x 
     ); 
     next unless $att; 
     $exclude{$att} = $criteria; 
    } 
} 

#process_message is called for each 'message' element, and tests filters for exclusion. 
sub process_message { 
    my ($twig, $message) = @_; 
    foreach my $att (keys %exclude) { 
     if ($message->att($att) eq $exclude{$att}) { 
      $message->delete(); 
      last; 
     } 
    } 
} 

my $twig = XML::Twig->new(
    pretty_print => 'indented', 
    twig_handlers => { 'message' => \&process_message } 
); 
$twig->parse(\*DATA); #might use 'parsefile ($filename)' or 'STDIN' instead 
$twig->print; 


__DATA__ 
<XML> 
<message type="error" from="Realtime" timestamp="Mon Nov 24 19:28:55 2014"> Could not receive from Loader </message> 
<message type="warning" from="Not_Dcd_Mux" timestamp="Mon Dec 1 02:31:18 2014"> Could not connect to Dcd </message> 
<message type="warning" from="Dcd_Mux" timestamp="Mon Dec 1 02:31:18 2014"> Could not connect to Dcd </message> 
</XML> 

Answer 4

該解決方案是從獵人麥克邁林的一個變化，並且在這裏主要是爲了說明我的意思通過「看起來像Perl編寫的Java程序」。

參數驗證是其中的一部分，雖然我已將它簡化爲一個簡單的計數檢查，但我通常不會寫任何東西。這是值得懷疑的，因爲問題是如何處理數據，而任何這樣的裁剪都取決於誰將使用該程序以及多久。

我已經選擇序列化輸出並將其打印到STDOUT，因爲能夠根據命令行的要求重定向輸出通常更加有用。

我意識到我認爲是一種Java風格的方法，注意驗證和一般「保護我免於我自己」。我不相信添加標籤並在next中使用它完全有幫助，特別是在這樣一個短的循環中。

use strict; 
use warnings; 

use XML::LibXML::PrettyPrint; 

@ARGV == 2 or die <<END_USAGE; 
Usage: 
    $0 <XML file> <node type> 
END_USAGE 

my ($xml_file, $exclude_type) = @ARGV; 

my $dom = XML::LibXML->load_xml(location => $xml_file); 

for my $node ($dom->findnodes('/root/message[@type]')) { 
    my $type = $node->getAttribute('type'); 
    $node->unbindNode if $type eq $exclude_type; 
} 

local $XML::LibXML::skipXMLDeclaration = 1; 
my $pp = XML::LibXML::PrettyPrint->new; 
print $pp->pretty_print($dom)->toString; 

輸出

<root> 
    <message type="warning" from="Dcd_Mux" timestamp="Mon Dec 1 02:31:18 2014"> 
    Could not connect to Dcd 
    </message> 
</root>