在Perl中查找具有最小寬度和高度的jpg

Question

我正在尋找一種方法來查找（1）具有最小寬度和（2）最小高度的文件，並顯示這些數字（最好是命令行，Linux或Windows）。我不知道要使用什麼工具，但我認爲Perl的一個包可能具有這種功能。

Answer 1

下面是一個完整的Perl程序，可以按照您的要求進行操作。您可能必須安裝Image::Magick，因爲它不是核心模塊。就目前而言，程序將檢查當前工作目錄中結尾爲.jpg的所有文件。您可能需要將呼叫更改爲glob以檢查不同目錄中的文件或不同的文件類型。

use strict; 
use warnings; 

use Image::Magick; 

my %data; 
for my $jpg (glob '*.jpg') { 
    my $magick = Image::Magick->new; 
    $magick->Read($jpg); 
    $data{$jpg} = { map { $_ => $magick->Get($_) } qw/ width height/}; 
} 

my ($least_width, $least_width_file); 
my ($least_height, $least_height_file); 

while (my ($jpg, $info) = each %data) { 

    unless ($least_width and $least_width <= $info->{width}) { 
     ($least_width_file, $least_width) = ($jpg, $info->{width}); 
    } 

    unless ($least_height and $least_height <= $info->{height}) { 
     ($least_height_file, $least_height) = ($jpg, $info->{height}); 
    } 
} 

print "\n"; 
printf "File with least width (%d) is %s\n", $least_width, $least_width_file; 
printf "File with least height (%d) is %s\n", $least_height, $least_height_file; 

---

更新

，關注@ nwellnhof的建議，並使用Image::Size代替Image::Magick，則應更換use語句和for循環用下面的代碼。

use Image::Size qw/ imgsize /; 

my %data; 
for my $jpg (glob '*.jpg') { 
    @{ $data{$jpg} }{qw/ width height /} = imgsize($jpg); 
} 

---

更新

該版本增加了一些統計信息輸出的要求。它使用List::UtilsBy模塊來更簡潔地查找最小的文件。這不是一個核心模塊，可能需要安裝。

use strict; 
use warnings; 

use Image::Size qw/ imgsize /; 
use List::UtilsBy qw/ min_by /; 

my %data; 
for my $jpg (glob '*.jpg') { 
    @{ $data{$jpg} }{qw/ width height /} = imgsize($jpg); 
} 

my @least_width_files = min_by { $data{$_}{width} } keys %data; 
my $least_width = $data{$least_width_files[0]}{width}; 

my @least_height_files = min_by { $data{$_}{height} } keys %data; 
my $least_height = $data{$least_height_files[0]}{height}; 

print "\n"; 
if (@least_width_files == keys %data) { 
    printf "All files have a width of %d\n", $least_width; 
} 
else { 
    my $n = @least_width_files; 
    printf "%d file%s %s the least width of %d:\n", $n, $n == 1 ? ('', 'has') : ('s', 'have'), $least_width; 
    print " $_\n" for @least_width_files; 
} 

print "\n"; 
if (@least_height_files == keys %data) { 
    printf "All files have a height of %d\n", $least_height; 
} 
else { 
    my $n = @least_height_files; 
    printf "%d file%s %s the least height of %d:\n", $n, $n == 1 ? ('', 'has') : ('s', 'have'), $least_height; 
    print " $_\n" for @least_height_files; 
} 

Answer 2

在Linux上，我只是從命令行使用ImageMagick。您可能需要（例如用在sudo apt-get install imagemagick Ubuntu的），先安裝它：

narrowest=$(identify *jpg | sort -nr -k3 | tail -n 1 | cut -d\[ -f1) 
shortest=$(identify *jpg | sort -tx -nr -k2 | tail -n 1 | cut -d\[ -f1) 

在Windows上，這不是除非你安裝Cygwin或東西的選項。

在Linux和Windows上，您都可以使用Image::Magick模塊從Perl訪問該功能，但您必須自己安裝該模塊。請參閱Borodin的代碼答案。

Answer 3

我會爲該任務推薦模塊Image::Size。與像Image::Magick這樣的全功能圖像處理庫相比，它不會將整個圖像解壓縮並將其讀取到內存中，以獲取其大小。所以它應該更快，更少的內存，特別是對於大型圖像。

東西沿着以下行應該工作：

use strict; 
use warnings; 

use Image::Size; 

my ($min_width, $min_height); 

for my $filename (glob '*.jpg') { 
    my ($width, $height) = imgsize($filename); 
    $min_width = $width if !defined($min_width) || $width < $min_width; 
    $min_height = $height if !defined($min_height) || $height < $min_height; 
} 

if (defined($min_width) && defined($min_height)) { 
    print "Minimum width: $min_width\n"; 
    print "Minimum height: $min_height\n"; 
} 
else { 
    print "No images found\n"; 
}