在xcopy中排除多個文件擴展名

Question

我有幾個擴展名，我想從xcopy中排除。我不知道可能存在的文件夾/目錄。

下面是命令我使用：

xcopy /r /d /i /s /y C:\test1 C:\test2 /exclude:.txt+.exe 

這個映幫助？

Answer 1

你所尋找的是這樣的：

xcopy /R /D /I /S /Y /EXCLUDE:exclude.txt "C:\test1" "C:\test2" 

與 exclude.txt以下內容

一起：

.txt 
.exe 

然而，xcopy的/EXCLUDE選擇是非常差。它不會真正排除具有給定擴展名的文件，它實際上排除了全路徑在任何位置包含.txt或.exe的所有項目。假設有一個源文件C:\test1\my.txt.files\file.ext，它也將被排除。

---

有幾種方法來解決這個問題，其中一些我想告訴你：

1. 使用robocopy command及其/XF選項：

   robocopy "C:\test1" "C:\test2" /S /XO /XF "*.txt" "*.exe" 
   

2. 創建batch-file ，使用for /F loop以及xcopy /L對文件進行預過濾：

   set /A "COUNT=0" 
   for /F "delims=" %%F in (' 
       rem/ // List files that would be copied without `/L`; remove summary line: ^&^
        xcopy /L /R /D /I /S /Y "C:\test1" "C:\test2" ^| find ".\" 
   ') do (
       rem // Check file extension of each file: 
       if /I not "%%~xF"==".txt" if /I not "%~xF"==".exe" (
        rem // Create destination directory, hide potential error messages: 
        2> nul mkdir "C:\test2\%%~F\.." 
        rem // Actually copy file, hide summary line: 
        > nul copy /Y "C:\test1\%%~F" "C:\test2\%%~F" && (
         rem // Return currently copied file: 
         set /A "COUNT+=1" & echo(%%~F 
        ) || (
         rem // Return message in case an error occurred: 
         >&2 echo ERROR: could not copy "%%~F"! 
        ) 
       ) 
   ) 
   echo   %COUNT% file^(s^) copied.