如何測試一個Zip文件在windows批處理文件中是否有效

Question

我使用的是7-zip的命令行版本，我可以用這個命令測試zip文件是否有效。

但我想創建一個批處理文件，它將循環通過目錄中的一堆壓縮文件，並且如果壓縮文件爲空，則執行一件事;如果壓縮文件中包含一些文件，則執行另一件事。

任何指針如何使用批處理文件做到這一點？

Answer 1

這可能有助於

@echo off 

setlocal enabledelayedexpansion 

set "zipPath=C:\temporal\" 
set "zipProg=C:\Program Files (x86)\7-Zip\7z.exe" 

call:shortIt "%zipPath%", zipPath 
call:shortIt "%zipProg%", zipProg 

pushd %zipPath% 

for /F "tokens=*" %%a in ('dir /b "%zipPath%" ^| find ".zip"') do (
    set/a numFiles=0, isOk=0, size=0, compressed=0 
    for /F "tokens=*" %%i in ('%zipProg% t "%zipPath%%%a"') do (
    echo %%i | find /I "ok" >NUL && set/a isOK=1 
    echo %%i | find /I "files" >NUL && for /F "tokens=2 delims=:" %%n in ("%%i") do set/a numFiles=%%n 
    echo %%i | find /I "size" >NUL && for /F "tokens=2 delims=:" %%n in ("%%i") do set/a size=%%n 
    echo %%i | find /I "compressed" >NUL && for /F "tokens=2 delims=:" %%n in ("%%i") do set/a compressed=%%n 
) 
    if !isOk! neq 0 if !numFiles! equ 0 if !size! neq 0 set/a numFiles=1 

    if !isOk! equ 0 (
     echo(
     echo(%zipPath%%%a is not an archive or an error ocurred 
     echo(
) else (
    if !numFiles! neq 0 (
     echo(%zipPath%%%a contains !numFiles! files [!size! to !compressed!] 
    ) else (
     echo(%zipPath%%%a is empty 
    ) 
) 
) 


popd 
endlocal 

exit/B 0 

:shortIt 
SetLocal & set "token=%~s1" 
EndLocal & set "%2=%token%"