Perl的地圖 - 需要一個數組的哈希映射爲arrayelement-> array_index

Question

我有一個這樣的數組：

my @arr = ("Field3","Field1","Field2","Field5","Field4"); 

現在我用地圖類似下面，其中/DoSomething的/就是答案時求。

my %hash = map {$_ => **/DOSOMETHING/** } @arr 

現在我需要的哈希看起來像如下：

 
Field3 => 0 
Field1 => 1 
Field2 => 2 
Field5 => 3 
Field4 => 4 

任何幫助嗎？

Answer 1

%hash = map { $arr[$_] => $_ } 0..$#arr; 

print Dumper(\%hash) 
$VAR1 = { 
      'Field4' => 4, 
      'Field2' => 2, 
      'Field5' => 3, 
      'Field1' => 1, 
      'Field3' => 0 
     }; 

Answer 2

my %hash; 
@hash{@arr} = 0..$#arr; 

Answer 3

在Perl 5.12，以後你可以用each陣列上遍歷它的索引/值對：

use 5.012; 

my %hash; 

while(my ($index, $value) = each @arr) { 
    $hash{$value} = $index; 
} 

Answer 4

另外還有一個我能想到的來完成這種方式：

sub get_bumper { 
    my $i = 0; 
    sub { $i++ }; 
} 

my $bump = get_bumper;   # $bump is a closure with its very own counter 
map { $_ => $bump->(); } @arr; 

對於很多事情，你可以在 Perl的事：不要做 這個。 :)如果您需要分配的值序列更復雜（例如0,1,4,9,16 ...或一系列隨機數或從管道讀取的數字），則很容易將此方法適用於它，但它通常更容易使用unbeli's approach。這種方法的唯一優點是它提供了一個很好的乾淨方式來提供和使用任意的惰性數字序列：一個需要調用者指定的數字序列的函數可以將一個coderef作爲參數，並將其重複地調用獲得數字。