xsl：apply-templates不會遍歷選擇的每個節點

我正在使用Saxon HE 9-4-0-3J。我的意圖是使用xsl:apply-templates上的select屬性遍歷每個<RECORD>元素，但xml中只有一個<RECORD>元素正在處理中。xsl：apply-templates不會遍歷選擇的每個節點

XML

<ENVELOPE> 
<PRODUCT> 
    <HEAD><FLAG>No</FLAG></HEAD> 
    <BODY> 
     <RECORD><Value>9</Value></RECORD> 
     <RECORD><Value>10</Value></RECORD> 
     <MISC>9</MISC> 
    </BODY> 
</PRODUCT>

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 

<xsl:template match="/ENVELOPE"> 
<Interface> 
    <Data><xsl:apply-templates select="PRODUCT"/></Data> 
</Interface> 
</xsl:template> 

<xsl:template match="PRODUCT"> 
    <xsl:choose> 
     <xsl:when test="HEAD/FLAG='Yes'"> 
     <xsl:attribute name="Match">Affirmative</xsl:attribute> 
     <xsl:apply-templates select="BODY/RECORD" mode="affr"/> 
     </xsl:when> 
     <xsl:when test="HEAD/FLAG='No'"> 
     <xsl:attribute name="Match">Negative</xsl:attribute> 
     <xsl:apply-templates select="BODY/RECORD" mode="neg"/> 
     </xsl:when> 
    </xsl:choose> 
</xsl:template> 

<xsl:template match="RECORD" mode="affr"> 
    <xsl:attribute name="Value"><xsl:value-of select="Value"/></xsl:attribute> 
</xsl:template> 

<xsl:template match="RECORD" mode="neg"> 
    <xsl:attribute name="Value"><xsl:value-of select="Value"/></xsl:attribute> 
</xsl:template> 

</xsl:stylesheet>

輸出

<Interface> 
     <Data Match="Negative" Value="9"/> <!-- this line doesn't appear, I want it to --> 
     <Data Match="Negative" Value="10"/> 
</Interface>

來源

2012-04-14 satish b

當您匹配<ENVELOPE...>時會生成<DATA...>輸出標籤，因此只能有其中一個輸出。任何<xsl:attribute>指令只會添加到此輸出標記中，其後的值會覆蓋較早的值。

你必須明確地生成你想要輸出的DATA標籤，如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0"> 

    <xsl:output method="xml" indent="yes"/> 
    <xsl:template match="/ENVELOPE"> 
    <Interface> 
     <xsl:apply-templates select="PRODUCT"/> 
    </Interface> 
    </xsl:template> 

    <xsl:template match="PRODUCT"> 
    <xsl:variable name="flag"> 
     <xsl:choose> 
     <xsl:when test="HEAD/FLAG='Yes'">Affirmative</xsl:when> 
     <xsl:when test="HEAD/FLAG='No'">Negative</xsl:when> 
     </xsl:choose> 
    </xsl:variable> 

    <xsl:apply-templates select="BODY/RECORD"> 
     <xsl:with-param name="flag"><xsl:value-of select="$flag"/></xsl:with-param> 
    </xsl:apply-templates> 

    </xsl:template> 

    <xsl:template match="RECORD"> 
    <xsl:param name="flag"/> 
    <Data Value="{Value}" Match="{$flag}"/> 
    </xsl:template> 

</xsl:stylesheet>

來源

2012-04-14 03:33:02

您的第一段非常有意義，謝謝您幫助我瞭解我出錯的位置。 – 2012-04-14 15:49:21

的問題是，你正在創建具有相同名稱兩個屬性 - Value。在格式良好的XML文檔中，元素不能具有多個具有相同名稱的屬性。

引述W3C XSLT 2.0 Specification（這正是在XSLT 1.0相同，太）：

9.如果在結果序列的屬性A具有相同的名稱出現另一個屬性乙稍後在結果序列中，則屬性A從結果序列中被丟棄。

因此，無論何時XSLT爲一個元素生成多個具有相同名稱的屬性，只有最後一個屬性被複制到輸出 - 這就是您所看到的。

下面是一個簡短和簡單的解決方案（只有兩個模板，沒有條件句，無參數）：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:variable name="vDoc" select="/"/> 

<xsl:variable name="vMatch" select= 
"('Affirmative', 'Negative')[2 - number($vDoc/*/*/HEAD/FLAG eq 'Yes')]"/> 

<xsl:template match="/*"> 
    <Interface> 
    <xsl:apply-templates select="*/BODY/RECORD"/> 
    </Interface> 
</xsl:template> 

<xsl:template match="RECORD"> 
    <Data Match="{$vMatch}" Value="{Value}"/> 
</xsl:template> 
</xsl:stylesheet>

當這個變換所提供的XML文檔應用：

<ENVELOPE> 
    <PRODUCT> 
     <HEAD> 
      <FLAG>No</FLAG> 
     </HEAD> 
     <BODY> 
      <RECORD> 
       <Value>9</Value> 
      </RECORD> 
      <RECORD> 
       <Value>10</Value> 
      </RECORD> 
      <MISC>9</MISC> 
     </BODY> 
    </PRODUCT> 
</ENVELOPE>

想要的，正確的結果產生：

<Interface> 
    <Data Match="Negative" Value="9"/> 
    <Data Match="Negative" Value="10"/> 
</Interface>

來源

2012-04-14 03:40:39

謝謝Dimitre。我在StackOverflow上學到了很多東西，數組/變量的構造看起來很強大。 – 2012-04-14 15:52:30

@satishb：不客氣。 – 2012-04-14 17:06:07

xsl：apply-templates不會遍歷選擇的每個節點

回答

相關問題