如何使用TypInfo RTTI方法將值設置爲子屬性項目？

Question

在我的問題： How to use 「Sender」 parameter with 「As」 operator for more then one class at a time

我選擇了雷米勒博的答案，因爲它是爲像大多數情況下，最有活力的高科技。它使用RTTI TypInfo類。

但是當我使用這個類時，出現了另一個問題： 我們如何設置一個子屬性值？

function TRemote.UpdateQuery(DataSet: TDataSet; SQL: String): Boolean; 
var 
    PropInfo: PPropInfo; 
begin 
{ atualiza o código SQL padrão de um dataSet de consulta tipo View } 
    PropInfo := GetPropInfo(DataSet, 'SQL', []); 
    if not Assigned(PropInfo) then 
    begin 
    Result := False; 
    Exit; 
    end; 
    try 
    DataSet.Close; 
    SetPropValue(DataSet, PropInfo, SQL); 
    DataSet.Open; 
    Result := True; 
    except 
    Result := False; 
    end; 
end; 

例子： 我有一個TIBQuery，我想更新SQL屬性的文本。 但SQL屬性是一個TStrings類，所以我必須使用SQL.Text。 在上面的代碼中，它會引發一個錯誤「無效的屬性類型」，因爲我得到了一個TStrings，後來我嘗試設置一個普通的String。

如何使用GetPropInfo訪問SQL.Text？ 是否有TIBQuery和TZQuery具有SQL屬性的共同祖先，所以我可以更改爲，而不是函數參數中的TDataSet？

Answer 1

在Delphi 2006中，無法通過RTTI訪問TStrings.Text屬性。即使是這樣，您也不需要使用RTTI來訪問它。既然你知道SQL屬性是TStrings對象，你可以簡單地retreive從屬性和實際的對象指針，類型轉換爲TStrings指針，那麼你可以做任何你需要與該對象的事，例如：

function TRemote.UpdateQuery(DataSet: TDataSet; SQL: String): Boolean; 
var 
    PropInfo: PPropInfo; 
    SQLObj: TStrings; 
begin 
    Result := False; 
    try 
    PropInfo := GetPropInfo(DataSet, 'SQL', [tkClass]); 
    if not Assigned(PropInfo) then Exit; 
    SQLObj := TStrings(GetObjectProp(DataSet, PropInfo, TStrings)); 
    if not Assigned(SQLObj) then Exit; 
    DataSet.Close; 
    SQLObj.Text := SQL; 
    DataSet.Open; 
    Result := True; 
    except 
    end; 
end;