以斜體打印字符串

Question

我從Userform以字符串的形式輸入，我需要在單元格中輸出它們。在輸出中，所有字符串都被連接起來，但只有少數字符被斜體化。我無法輸出斜體字符串。我曾嘗試搜索文檔，堆棧交換和其他幾個博客，但它們都需要從單元格中進行選擇，而不是操縱從Userform獲取的字符串。任何幫助或指針，不勝感激。

現在輸出：[1] R. Welder。如何焊接。焊接車間：出版商，2014年，第25-32頁。

所需輸出：[1] R. Welder。 如何焊接。焊接車間：出版商，2014年，第25-32頁。

Private Sub Ok_Click() 
Dim emptyRow As Long 
Dim bookAuthor, bookTitle, loc, publish, yearBook, pageBook As String 

'Make Sheet2 active 
Sheet2.Activate 

'Determine emptyRow 
emptyRow = WorksheetFunction.CountA(Range("A:A")) + 1 

'Format Information 
bookAuthor = Author.Value + ". " 
bookTitle = TitleOfBook.Value + ". " 'Needs to be Italicized 
'bookTitle.Font.Italic 'Error: Object Required 
'TitleOfBook.Font.Italic = True 'Italicizes in userform but not in cell 
loc = Location.Value + ": " 
publish = Publisher.Value + ", " 
yearBook = Year.Value + ", " 
pageBook = "pp. " + Pages.Value + ". " 

'Transfer information 
Cells(emptyRow, 1).Value = "[" + CStr(emptyRow) + "] " + bookAuthor + bookTitle + loc + publish + yearBook + pageBook 

Unload Me 
End Sub' 

Answer 1

設置您寫入的單元格的字體樣式爲其斜體的單元格，而不是字符串;

With Range("A1") 
    .Font.Italic = True 
    .Value = "Roast Beef" 
End With 

編輯;斜體部分細胞選擇由偏移量和長度的內容：

emptyRow = 1 
bookAuthor = "R. Welder." 
bookTitle = "How to weld" 
loc = "Welding Shop" 
publish = "Publisher" 
yearBook = "2014" 
pageBook = "pp25-32" 

Dim temp As String, begin As Long 
'// store everything upto the start of italic part 
temp = "[" & emptyRow & "] " & bookAuthor & " " 
'// store its length 
begin = Len(temp) 

With Range("A1") 
    '// set the value to everything 
    .Value = temp & bookTitle & " " & loc & " " & publish & " " & yearBook & " " & pageBook 
    '// we know where the italic text need to be 
    .Characters(begin + 1, Len(bookTitle)).Font.Italic = True 
End With