返回節點中一次獲取的所有XML元素

Question

每個節點都包含字段LIGHT_COLOUR中的一個顏色列表，由字母R（紅色），W（白色）等等標識。 在字段LIGHT_COLOUR中可以是唯一的一個顏色/字母或不止一個用' - '分隔。

這是我的用於測試XML：

<LIGHT_INFORMATION_LIST> 
    <LIGHT_INFORMATION> 
     <LIGHT_CHARACTERISTICS>Al</LIGHT_CHARACTERISTICS> 
     <LIGHT_COLOUR>W-G</LIGHT_COLOUR> 
    </LIGHT_INFORMATION> 
    <LIGHT_INFORMATION> 
     <LIGHT_CHARACTERISTICS>Al</LIGHT_CHARACTERISTICS> 
     <LIGHT_COLOUR>W-R</LIGHT_COLOUR> 
    </LIGHT_INFORMATION> 
    <LIGHT_INFORMATION> 
     <LIGHT_CHARACTERISTICS>F</LIGHT_CHARACTERISTICS> 
     <LIGHT_COLOUR>R</LIGHT_COLOUR> 
    </LIGHT_INFORMATION> 
    <LIGHT_INFORMATION> 
     <LIGHT_CHARACTERISTICS>F</LIGHT_CHARACTERISTICS> 
     <LIGHT_COLOUR>G</LIGHT_COLOUR> 
    </LIGHT_INFORMATION> 
    <LIGHT_INFORMATION> 
     <LIGHT_CHARACTERISTICS>F</LIGHT_CHARACTERISTICS> 
     <LIGHT_COLOUR>W</LIGHT_COLOUR> 
    </LIGHT_INFORMATION> 
</LIGHT_INFORMATION_LIST> 

這是我的XSLT：

<xsl:for-each select="LIGHT_INFORMATION_LIST"> 
    <xsl:for-each select="LIGHT_INFORMATION"> 
     <xsl:for-each select="LIGHT_COLOUR"> 
      <xsl:value-of select="."/> 
     </xsl:for-each> 
    </xsl:for-each> 
</xsl:for-each> 

現在我的輸出是：W-G W-R R G^w^
這是LIGHT_COLOUR字段中的所有元件。

我會輸出一次所有元素（LIGHT_COLOUR不同）。

在輸出我想：WGR

做到這將是第一次在你的榜樣，以創建一個包含所有連接成一個字符串

<xsl:variable name="allColours"> 
    <xsl:for-each select="LIGHT_INFORMATION_LIST/LIGHT_INFORMATION"> 
     <xsl:value-of select="concat(LIGHT_COLOUR, '-')" /> 
    </xsl:for-each> 
    </xsl:variable> 

所以單獨LIGHT_COLOUR元素，一個變量

Answer 1

的一種方法，它將被設置爲「WGTWREEREE-」。

然後，您可以有一個遞歸模板，將字符串拆分爲字符，但同時保留不同值的運行列表。因此，在每次迭代時，它會在連字符前獲取下一個字符，並檢查它是否不在不同值的列表中。如果沒有，它將它添加到這個列表中，並且遞歸模板繼續處理直到沒有任何東西離開。

試試這個XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="/"> 
     <xsl:variable name="allColours"> 
     <xsl:for-each select="LIGHT_INFORMATION_LIST/LIGHT_INFORMATION"> 
      <xsl:value-of select="concat(LIGHT_COLOUR, '-')" /> 
     </xsl:for-each> 
     </xsl:variable> 

     <xsl:call-template name="tokenizeDistinct"> 
     <xsl:with-param name="string" select="$allColours" /> 
     </xsl:call-template> 
    </xsl:template> 

    <xsl:template name="tokenizeDistinct"> 
     <xsl:param name="string" /> 
     <xsl:param name="splitChar" select="'-'" /> 
     <xsl:param name="distinctList" select="' '" /> 

     <xsl:variable name="nextChar" select="substring-before(concat($string, $splitChar), $splitChar)" /> 
     <xsl:variable name="newDistinctList"> 
     <xsl:value-of select="$distinctList" /> 
     <xsl:if test="$nextChar != '' and not(contains($distinctList, concat(' ', $nextChar, ' ')))"> 
      <xsl:value-of select="concat($nextChar, ' ')" /> 
     </xsl:if> 
     </xsl:variable> 
     <xsl:choose> 
     <xsl:when test="contains($string, $splitChar)"> 
      <xsl:call-template name="tokenizeDistinct"> 
       <xsl:with-param name="string" select="substring-after($string, $splitChar)" /> 
       <xsl:with-param name="splitChar" select="$splitChar" /> 
       <xsl:with-param name="distinctList" select="$newDistinctList" /> 
      </xsl:call-template> 
     </xsl:when> 
     <xsl:otherwise> 
      <xsl:value-of select="$newDistinctList" /> 
     </xsl:otherwise> 
     </xsl:choose> 
    </xsl:template> 
</xsl:stylesheet> 

當適用於您的XML，下面是輸出

W G R 

Answer 2

如果 - 我懷疑 - 有可能的顏色已知名單，而在這份名單每種顏色都由一個字母表示，那麼這可能很簡單。例如，下面的樣式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" > 
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/> 

<xsl:param name="color-list">RGBCMYKW</xsl:param> 

<xsl:template match="/"> 
    <xsl:variable name="present-colors"> 
     <xsl:for-each select="LIGHT_INFORMATION_LIST/LIGHT_INFORMATION"> 
      <xsl:value-of select="translate(LIGHT_COLOUR, '-', '')"/> 
     </xsl:for-each> 
    </xsl:variable> 
    <result> 
     <xsl:value-of select="translate($color-list, translate($color-list, $present-colors, ''), '')"/> 
    </result> 
</xsl:template> 

</xsl:stylesheet> 

當應用到您的示例輸入，將返回：

<?xml version="1.0" encoding="UTF-8"?> 
<result>RGW</result>