Haskell AS綁定在無可辯駁的模式

Question

我試圖使用無可辯駁的模式和AS綁定到一個函數，評估反向波蘭符號表達式。

這裏是我的代碼：

resolveRPN :: String -> [Integer] 
resolveRPN = foldl helper [] . words 
    where 
     helper ~stack@(x1:x2:xs) el 
      | el == "+" = (x2 + x1) : xs 
      | el == "-" = (x2 - x1) : xs 
      | el == "*" = (x2 * x1) : xs 
      | el == "/" = (x2 `div` x1) : xs 
      | otherwise = (read el) : stack    

基本上無可辯駁的，如果你給一個列表少於2個元素，但這應該僅用於將失敗「+ - * /」。 如果該函數應用於「10 10」，它應該只使用「其他」並使用AS綁定「堆棧」，不應該試圖將其分解爲構造函數，但似乎它不起作用。

例如，如果我使用助手摺疊並使用[0,0]作爲累加器，即使不需要此值，即使正常工作也能正常工作。

有人可以解釋爲什麼這段代碼仍然提出「無可辯駁的模式」，除非？或Haskell如何評估這個？

下面是簡化代碼：

notWorking :: [Int] 
notWorking = helper [] "10" 
     where 
      helper ~stack@(x1:x2:xs) el = (read el) : stack 

working:: [Int] 
working = helper [] "10" 
    where 
     helper ~stack el = (read el) : stack 

Answer 1

的經驗法則是：

• 顛撲不破/懶人模式如果p變量x被徵求~p匹配一切
• ，考慮所有構造函數中的p從除x到達的語法樹向下移動向下跨越~：匹配的值將被評估爲與這些構造函數匹配
• 如果匹配abov Ë失敗，拋出一個異常

例子：

case value of ~(x,y:ys,~(z,w:ws)) -> ... 

• 如果我們沒有什麼要求，然後value不會被評估
• 如果我們要求x或y或ys，然後value將根據需要進行評估以匹配y:ys（和三聯體）
• 如果我們要求z或w或ws，然後value將盡可能多的需要相匹配y:ys和w:ws評估（和三和一對）

測試：

> case undefined of ~(x,y:ys,~(z,w:ws)) -> "hello" 
"hello" 
> case (3,undefined,(4,[1])) of ~(x,y:ys,~(z,w:ws)) -> x 
*** Exception: Prelude.undefined 
> case (3,[],(4,[1])) of ~(x,y:ys,~(z,w:ws)) -> x 
*** Exception: Irrefutable pattern failed for pattern (x, y : ys, ~(z, w : ws)) 
> case (3,[0],(4,undefined)) of ~(x,y:ys,~(z,w:ws)) -> x 
3 
> case (3,[0],(4,[])) of ~(x,y:ys,~(z,w:ws)) -> x 
3 
> case (3,[],(4,[1])) of ~(x,y:ys,~(z,w:ws)) -> z 
*** Exception: Irrefutable pattern failed for pattern (x, y : ys, ~(z, w : ws)) 
> case (3,[0],(4,[])) of ~(x,y:ys,~(z,w:ws)) -> z 
*** Exception: Irrefutable pattern failed for pattern (z, w : ws) 

在我看來，語義可能如果~下的每個子模式表現得好像它在上面有~那樣更好。例如。如果~(x,y:ys)等於~(x,~(y:ys))。不過，當前的語義確實允許更多的靈活性。

---

即使存在「as」模式，該規則也適用。例如，在

case value of a@ ~(x,y:ys,~b@(z,c@(w:ws))) -> ... 

苛刻a不會評估value但苛刻的任何其他變量 會導致value被如此評價相匹配的三倍。 此外，要求任何x,y,ys也將導致評估匹配 y:ys中的列表構造函數。相反，匹配b或z,c,w,ws中的任何一個將導致value進一步評估，以便匹配(z,c@(w:ws))以及列表w:ws（其在第二個~之下）。

--Here is an example with "as" pattern outside that will succeed 
> case (1,[],(2,[3])) of a@ ~(x,y:ys,~b@(z,c@(w:ws))) -> a 
(1,[],(2,[3])) 

--This will fail because the triple as well as y:ys will be evaluated along a 
> case (1,[],(2,[3])) of ~a@(x,y:ys,~b@(z,c@(w:ws))) -> a 
*** Exception: Irrefutable pattern failed for pattern a@(x, y : ys, ~b@(z, c@(w : ws))) 

---

在你的代碼，你可以簡單地把~這樣外「的」結合：

helper stack@ ~(x1:x2:xs) el 
    | el == "+" = (x2 + x1) : xs 
    | el == "-" = (x2 - x1) : xs 
    | el == "*" = (x2 * x1) : xs 
    | el == "/" = (x2 `div` x1) : xs 
    | otherwise = (read el) : stack 

，將工作的優良任何有效的RPN輸入。

Answer 2

當我們嘗試打印生成的列表中無可辯駁的模式失敗：

head $ resolveRPN "2 4 +" -- 6, no error 
resolveRPN "2 4 +" -- error 

在上面的例子中，我們沒有一個適當的[]在結果列表的末尾。相反，我們有一個無可辯駁的(:)模式，它會引發錯誤。換句話說，即使我們沒有真正嘗試訪問模式中的頭部或尾部，~(x:xs)也不能用作空列表。

Answer 3

無可辯駁的模式是申請stack@(x1:x2:xs)不是每一個，所以當你試圖提取stack這將自動評估(x1:x2:xs)。

這個問題只能進行模式匹配，但不作爲綁定定義hepler這樣用無可辯駁的是固定的：

helper stack@ ~(x1:x2:xs) el 
     | el == "+" = (x2 + x1) : xs 
     | el == "-" = (x2 - x1) : xs 
     | el == "*" = (x2 * x1) : xs 
     | el == "/" = (x2 `div` x1) : xs 
     | otherwise = (read el) : stack 

，這將永遠不會失敗的有效表達。