第一次運行SQL Server T-SQL查詢速度慢，然後快速運行

Question

我有一個非常簡單的存儲過程;它第一次運行緩慢，如果輸入參數相同，則運行速度很快。

它返回兩個表，表頭正在迅速恢復，但第二個表，它作爲我與表1的結果加入它得到正確的數據變得緩慢

這裏是我的存儲過程的代碼：

SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 

ALTER PROCEDURE [dbo].[PR_ReadMdgObj] 
     (@objId int, 
     @dtFrom datetime = NULL, 
     @dtTo datetime = NULL) 
AS 
BEGIN 
    SET NOCOUNT ON 

    SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED 

    DECLARE @engine_SensorSource_id INT 

    SELECT @engine_SensorSource_id = SensorSourceid 
    FROM dbo.SensorSource 
    WHERE sourcenameid = 1 
     AND objectid = @objId 

    CREATE TABLE #10msgtable 
    (
     rownum int IDENTITY (1, 1) NOT NULL, 
     MessageId bigint NOT NULL, 
     ObjectId int NOT NULL, 
     VectorAngle int NOT NULL, 
     VectorSpeed int NOT NULL, 
     Altitude int NOT NULL, 
     GpsTime datetime NOT NULL, 
     VisibleSatelites int NULL, 
     X float, Y float, 
     engine int, 
     st int 
    ); 

    CREATE CLUSTERED INDEX IDX_C_returnTable10_GpsTime 
    ON #10msgtable (GpsTime); 

    INSERT INTO #10msgtable 
     SELECT 
      [Message].messageid, [Message].objectid, 
      [Message].vectorangle, [Message].vectorspeed, 
      [Message].altitude, [Message].gpstime, 
      [Message].visiblesatelites, 
      [Message].x, [Message].y, 
      0 Engine, 0 as t 
     FROM 
      dbo.[Message] WITH (nolock) 
     WHERE 
      [Message].ObjectId = @objId 
      AND [Message].GpsTime BETWEEN @dtFrom AND @dtTo 
      -- AND m.Valid = 1 
      -- AND m.VectorSpeed < 250 

    DELETE FROM #10msgtable 
    WHERE VectorSpeed = 250; 

    SELECT * 
    FROM #10msgtable 
    ORDER BY GpsTime ASC 

    --- select 2 
    SELECT 
     MessageSensors.MessageId, 
     SensorSource.SourceNameId, 
     MessageSensors.Value 
    FROM 
     dbo.MessageSensors 
    INNER JOIN 
     #10msgtable WITH (nolock) ON MessageSensors.MessageId= #10msgtable.MessageId 
    INNER JOIN 
     dbo.SensorSource WITH (nolock) ON SensorSource.SensorSourceId = MessageSensors.SensorSourceId 
    --where MessageSensors.MessageId in (select MessageId from #10msgtable) 

    SET TRANSACTION ISOLATION LEVEL READ COMMITTED 
END 

這裏是我的實際執行計劃：

https://gist.github.com/aymanstar/3ed882c6330ee6252751ce9dd2f5beac

Answer 1

有你添加一些不必要的步驟。第一次運行總是很慢（正如你已經知道的那樣）。 在你的腳本

1. 沒有必要添加with(nolock)的原因是由@marc_s
2. 不必要的變量聲明（@engine_SensorSource_id）explaned。
3. 如果您在第一次嘗試中過濾掉數據，則無需執行delete。

所以修改後的腳本應該是這樣的： -

SET ANSI_NULLS ON 
GO 

SET QUOTED_IDENTIFIER ON 
GO 

ALTER PROCEDURE [dbo].[PR_ReadMdgObj] (
    @objId INT 
    ,@dtFrom DATETIME = NULL 
    ,@dtTo DATETIME = NULL 
    ) 
AS 
BEGIN 
    SET NOCOUNT ON 
    SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED 

    --DECLARE @engine_SensorSource_id INT 

    --SELECT @engine_SensorSource_id = SensorSourceid 
    --FROM dbo.SensorSource 
    --WHERE sourcenameid = 1 
    -- AND objectid = @objId 

    CREATE TABLE #10msgtable (
     rownum INT IDENTITY(1, 1) NOT NULL 
     ,MessageId BIGINT NOT NULL 
     ,ObjectId INT NOT NULL 
     ,VectorAngle INT NOT NULL 
     ,VectorSpeed INT NOT NULL 
     ,Altitude INT NOT NULL 
     ,GpsTime DATETIME NOT NULL 
     ,VisibleSatelites INT NULL 
     ,X FLOAT 
     ,Y FLOAT 
     ,engine INT 
     ,st INT 
     ); 

    CREATE CLUSTERED INDEX IDX_C_returnTable10_GpsTime ON #10msgtable (
     MessageId 
     ,GpsTime 
     ); 

    INSERT INTO #10msgtable 
    SELECT [Message].messageid 
     ,[Message].objectid 
     ,[Message].vectorangle 
     ,[Message].vectorspeed 
     ,[Message].altitude 
     ,[Message].gpstime 
     ,[Message].visiblesatelites 
     ,[Message].x 
     ,[Message].y 
     ,0 Engine 
     ,0 AS t 
    FROM dbo.[Message] 
    WHERE [Message].ObjectId = @objId 
     AND [Message].GpsTime BETWEEN @dtFrom 
      AND @dtTo 
     AND VectorSpeed <> 250 

    -- AND m.Valid = 1 
    -- AND m.VectorSpeed < 250 
    --DELETE 
    --FROM #10msgtable 
    --WHERE VectorSpeed = 250; 

    SELECT * 
    FROM #10msgtable 
    ORDER BY GpsTime ASC 

    --- select 2 
    SELECT MessageSensors.MessageId 
     ,SensorSource.SourceNameId 
     ,MessageSensors.Value 
    FROM dbo.MessageSensors 
    INNER JOIN #10msgtable ON MessageSensors.MessageId = #10msgtable.MessageId 
    INNER JOIN dbo.SensorSource ON SensorSource.SensorSourceId = MessageSensors.SensorSourceId 

    --where MessageSensors.MessageId in (select MessageId from #10msgtable) 
    SET TRANSACTION ISOLATION LEVEL READ COMMITTED 
END