發送命令和字符串Terminal.app使用AppleScript

Question

我想要做這樣的事情：

tell application "Terminal" 
    activate 
    do script "ssh user@server.com" 
    -- // write user's password 
    -- // write some linux commands to remote server 
end tell 

例如登錄到服務器，輸入密碼，然後登錄到MySQL和選擇DB 。
我每天都會輸入這個數字，它會是真的有助於將它綁定到腳本中。

此外，有什麼命令，屬性，功能等應用程序（終端，Finder等）可供在Applescript中使用的參考？謝謝！

編輯：讓我明確這一點： 我不想做幾個'做腳本'，因爲我試過了，不起作用。 我想打開一個終端窗口，然後模仿人類在某些字符中鍵入並敲擊回車。可能是密碼，可能是命令，不管怎麼說，只是發送字符到正在運行ssh的終端。我嘗試了擊鍵，似乎沒有工作。

Answer 1

首先連接到服務器，並等待6秒（可以更改），然後執行不管你使用相同的標籤

需要在遠程服務器上

tell application "Terminal" 
    set currentTab to do script ("ssh user@server;") 
    delay 6 
    do script ("do something remote") in currentTab 
end tell 

Answer 2

我可能被誤認爲了，但我認爲Applescript終端集成是一次性處理......也就是說，每個do script調用就像打開一個不同的終端窗口，所以我不認爲你可以與它進行交互所有。

你可以通過SSH公鑰複製到防止密碼提示，然後執行的所有命令連接在一起（警告：下面是完全未經測試）：

tell application "Terminal" 
    activate 
    do script "ssh jdoe@example.com '/home/jdoe/dosomestuff.sh && /home/jdoe/dosomemorestuff.sh'" 
end tell 

或者，你可以換了ssh和後續命令，使用Expect，然後從你的Applescript中調用所述shell腳本。

Answer 3

設置無密碼ssh（ssh-keygen，然後將密鑰添加到服務器上的~/.ssh/authorized_keys）。在~/.ssh/config（在你的桌面上）輸入一個條目，這樣當你運行ssh mysqlserver時，它會轉到user @ hostname ...或者創建一個shell別名，比如gotosql，擴展到ssh user@host -t 'mysql_client ...'以在服務器上交互地啓動mysql客戶端。

然後你可能確實需要別人的回答來編寫腳本，因爲我不知道如何爲mysql設置啓動命令。

至少可以讓您的ssh密碼不在腳本中！

Answer 4

正如EvanK所說，每個腳本行都會打開一個新窗口，但是您可以用分號分隔它們來運行
兩個命令。例如：

tell application "Terminal" 
    do script "date;time" 
end tell 

但是限制似乎是兩個命令。

但是，可以追加「窗口1」到做腳本命令（每做後的第一個腳本）來達到同樣的效果，並繼續爲你在同一個需要運行多個命令窗口：

tell application "Terminal" 
    do script "date" 
    do script "time" in window 1 
    do script "who" in window 1 
end tell 

請注意，我只是用誰，日期和時間命令爲例...你所需要的任何命令替換 。

Answer 5

Petruza，

而不是使用按鍵使用按鍵代碼。
以下示例應該適合您。

tell application "System Events" 
    tell application process "Terminal" 
     set frontmost to true 
     key code {2, 0, 17, 14} 
     keystroke return 
    end tell 
end tell 

上面的例子將發送字符{D A T E} 到終端，然後
擊鍵返回將進入和運行 該命令。使用上面的示例
以及您需要的任何鍵碼 ，您就可以做你想做的事情。

Answer 6

怎麼樣這樣的：

tell application "Terminal" 

    activate 
    do shell script "sudo dscl localhost -create /Local/Default/Hosts/cc.josmoe.com IPAddress 127.0.0.1" 
    do shell script "sudo dscl localhost -create /Local/Default/Hosts/cc.josmos2.com IPAddress 127.0.0.1" 

end tell 

Answer 7

這個怎麼樣？不需要關鍵代碼（至少在Lion中，前面不太確定），並且子例程簡化了主腳本。

以下腳本將以用戶「me」的身份ssh到localhost，延遲1秒後輸入密碼「myPassw0rd」，發出ls，延遲2秒，然後退出。

tell application "Terminal" 
    activate 
    my execCmd("ssh me@localhost", 1) 
    my execCmd("myPassw0rd", 0) 
    my execCmd("ls", 2) 
    my execCmd("exit", 0) 
end tell 
on execCmd(cmd, pause) 
    tell application "System Events" 
     tell application process "Terminal" 
      set frontmost to true 
      keystroke cmd 
      keystroke return 
     end tell 
    end tell 
    delay pause 
end execCmd 

Answer 8

最後一個示例在關鍵字「pause」導致10.6.8（Build 10K549）下出現錯誤。

由單詞替換爲「等待」使得它的工作：

tell application "Terminal" 
    activate 
    my execCmd("ssh me@localhost", 1) 
    my execCmd("myPassw0rd", 0) 
    my execCmd("ls", 2) 
    my execCmd("exit", 0) 
end tell 

on execCmd(cmd, wait) 
    tell application "System Events" 
     tell application process "Terminal" 
      set frontmost to true 
      keystroke cmd 
      keystroke return 
     end tell 
    end tell 

    delay wait 
end execCmd 

Answer 9

你的問題具體如何獲得的AppleScript做你想要什麼 。但是，對於所描述的特定示例，您可能希望 將「期望」視爲解決方案。

Answer 10

下面是另一種方式，但是它具有啓動終端的優點，將它帶到最前面，並且只創建一個窗口。

我喜歡這個，當我想整齊地呈現我的腳本的結果。

tell application "Terminal" 
    activate 
    set shell to do script "echo 1" in window 1 
    do script "echo 2" in shell 
    do script "echo 3" in shell 
end tell 

Answer 11

你不需要「告訴」終端做任何事情。 AppleScript可以直接執行shell腳本。

set theDir to "~/Desktop/" 
do shell script "touch " & theDir &"SomeFile.txt" 

或其他...

Answer 12

整齊的解決方案，試戴

$ open -a /Applications/Utilities/Terminal.app *.py 

或

$ open -b com.apple.terminal *.py 

對於推出的外殼，你可以去首選項>殼牌>設置，如果沒有錯誤退出。

就是這樣。

Answer 13

爲什麼不使用期望：

tell application "Terminal" 
    activate 
    set currentTab to do script ("expect -c 'spawn ssh user@IP; expect \"*?assword:*\"; send \"MySecretPass 
\"; interact'") 
end tell 

Answer 14

有點兒關係，你可能想看看班車（http://fitztrev.github.io/shuttle/），它是一個OSX SSH快捷菜單。

Answer 15

我建立了這個腳本。它位於優勝美地，它是使用AppleScript的bash腳本爲SSH服務器選擇用戶列表。基本上你定義一個IP，然後將用戶名。當應用程序啓動它會詢問你想要的.. SSH終端啓動並登錄提示密碼登錄在誰...

(*** 
* --- --- --- --- --- 
* JD Sports Fashion plc 
* Apple Script 
* Khaleel Mughal 
* --- --- --- --- --- 
* #SHELLSTAGINGSSHBASH 
* --- --- --- --- --- 
***) 

set stagingIP to "192.162.999.999" 

set faciaName to (choose from list {"admin", "marketing", "photography_cdn"}) 

if faciaName is false then 
    display dialog "No facia was selected." with icon stop buttons {"Exit"} default button {"Exit"} 
else 
    set faciaName to (item 1 of faciaName) 

    tell application "Terminal" 
     activate 
     do script "ssh " & faciaName & "@" & stagingIP & "" 
    end tell 

end if 

我強烈儘管推薦; Nathan Pickmans post above關於Shuttle（http://fitztrev.github.io/shuttle/）..一個非常聰明和簡單的應用程序。