Delphi-Mocks：使用構造函數中的參數嘲笑一個類

Question

我開始使用Delphi-Mocks框架，並且在構造函數中模仿具有參數的類時遇到了問題。 TMock的類函數「創建」不允許參數。如果嘗試創建TFoo.Create的模擬實例（Bar：someType）; TObjectProxy.Create時，我得到一個參數計數不匹配';試圖呼叫T.

的「創建」方法

顯然，這是因爲下面的代碼不會傳遞任何參數的「調用」方法：

instance := ctor.Invoke(rType.AsInstance.MetaclassType, []); 

我創建了一個重載類功能是否通過參數：

class function Create(Args: array of TValue): TMock<T>; overload;static; 

並正在進行有限的測試我已經完成。

我的問題是：

這是一個bug或我只是做錯了？

感謝

PS：我知道，德爾福嘲笑爲界面爲中心，但它不支持類和代碼庫我工作的是99層％的類。

Answer 1

正如我所看到的，根本問題是TMock<T>.Create導致被測試類（CUT）被實例化。我懷疑這個框架的設計是基於假設你會嘲笑一個抽象基類。在這種情況下，實例化它將是良性的。我懷疑你正在處理遺留的代碼，它沒有CUT的方便的抽象基類。但在你的情況下，實例化CUT的唯一方法就是將參數傳遞給構造函數，從而打敗了嘲笑的全部目的。而且我想象一下，重新設計遺留代碼庫將需要很多工作，直到您爲需要模擬的所有類抽象基類爲止。

您正在撰寫TMock<TFoo>.Create其中TFoo是一類。這會導致創建代理對象。這發生在TObjectProxy<T>.Create。其代碼如下所示：

constructor TObjectProxy<T>.Create; 
var 
    ctx : TRttiContext; 
    rType : TRttiType; 
    ctor : TRttiMethod; 
    instance : TValue; 
begin 
    inherited; 
    ctx := TRttiContext.Create; 
    rType := ctx.GetType(TypeInfo(T)); 
    if rType = nil then 
    raise EMockNoRTTIException.Create('No TypeInfo found for T'); 

    ctor := rType.GetMethod('Create'); 
    if ctor = nil then 
    raise EMockException.Create('Could not find constructor Create on type ' + rType.Name); 
    instance := ctor.Invoke(rType.AsInstance.MetaclassType, []); 
    FInstance := instance.AsType<T>(); 
    FVMInterceptor := TVirtualMethodInterceptor.Create(rType.AsInstance.MetaclassType); 
    FVMInterceptor.Proxify(instance.AsObject); 
    FVMInterceptor.OnBefore := DoBefore; 
end; 

正如你所看到的代碼假設你的類有一個沒有參數的構造函數。當你在你的類上調用它時，它的構造函數確實有參數，這會導致運行時RTTI異常。

據我瞭解的代碼，類實例化僅用於截取其虛擬方法的目的。我們不想在課堂上做任何其他事情，因爲那樣會打敗嘲笑它的目的。您真正需要的是具有合適的vtable的對象的實例，可由TVirtualMethodInterceptor操縱。你不需要或者不想讓你的構造函數運行。你只是希望能夠模擬恰好具有參數的構造函數的類。

因此，而不是調用構造函數的代碼，我建議您修改它以使其調用NewInstance。這是爲了擁有一個可以被操縱的vtable所需要做的最低限度的事情。而且您還需要修改代碼，以便它不會試圖銷燬模擬實例，而是調用FreeInstance。只要你所做的就是在模擬上調用虛擬方法，所有這些都可以正常工作。

的修改是這樣的：

constructor TObjectProxy<T>.Create; 
var 
    ctx : TRttiContext; 
    rType : TRttiType; 
    NewInstance : TRttiMethod; 
    instance : TValue; 
begin 
    inherited; 
    ctx := TRttiContext.Create; 
    rType := ctx.GetType(TypeInfo(T)); 
    if rType = nil then 
    raise EMockNoRTTIException.Create('No TypeInfo found for T'); 

    NewInstance := rType.GetMethod('NewInstance'); 
    if NewInstance = nil then 
    raise EMockException.Create('Could not find NewInstance method on type ' + rType.Name); 
    instance := NewInstance.Invoke(rType.AsInstance.MetaclassType, []); 
    FInstance := instance.AsType<T>(); 
    FVMInterceptor := TVirtualMethodInterceptor.Create(rType.AsInstance.MetaclassType); 
    FVMInterceptor.Proxify(instance.AsObject); 
    FVMInterceptor.OnBefore := DoBefore; 
end; 

destructor TObjectProxy<T>.Destroy; 
begin 
    TObject(Pointer(@FInstance)^).FreeInstance;//always dispose of the instance before the interceptor. 
    FVMInterceptor.Free; 
    inherited; 
end; 

坦率地說，這看起來更明智一點給我。調用構造函數和析構函數肯定沒有意義。

請讓我知道，如果我在這裏廣泛的標誌，並錯過了這一點。這完全有可能！

Answer 2

聲明：我不知道Delphi-Mocks。

我想這是設計。從你的示例代碼看起來像Delphi-Mocks正在使用泛型。如果你想實例化一個泛型參數的實例，如：

function TSomeClass<T>.CreateType: T; 
begin 
    Result := T.Create; 
end; 

，那麼你需要在通用類的構造函數約束：

TSomeClass<T: class, constructor> = class 

有一個構造函數約束意味着類型傳遞必須有無參數的構造函數。

你也許可以做類似

TSomeClass<T: TSomeBaseMockableClass, constructor> = class 

，並給TSomeBaseMockableClass特定的構造以及可能再被使用，但：

需要你的框架的所有用戶獲得他們的所有類從一個特定的基類只是...呃...過於嚴格（輕描淡寫），特別是考慮到Delphi的單一繼承。

Answer 3

我不知道我是否正確地獲得了您的需求，但也許這種hacky方法可能有所幫助。假設你有一個需要在其構造函數的參數類

type 
    TMyClass = class 
    public 
    constructor Create(AValue: Integer); 
    end; 

你可以繼承這個類有一個參數的構造函數和類屬性保存參數

type 
    TMyClassMockable = class(TMyClass) 
    private 
    class var 
    FACreateParam: Integer; 
    public 
    constructor Create; 
    class property ACreateParam: Integer read FACreateParam write FACreateParam; 
    end; 

constructor TMyClassMockable.Create; 
begin 
    inherited Create(ACreateParam); 
end; 

現在你可以使用類屬性將參數傳遞給構造函數。當然，你必須把繼承的類給模擬框架，但是沒有其他改變，派生類也應該這樣做。

如果您確切知道何時實例化該類，那麼您可以爲該類屬性提供正確的參數，這也將起作用。

不用說，這種方法不是線程安全的。