使用XSL替換具有新節點的XML節點

Question

我需要一個XSL解決方案來用新節點替換XML節點。

說我有以下現有的XML結構：

<root> 
    <criteria> 
     <criterion>AAA</criterion> 
    </criteria> 
</root> 

而且我想，以取代與一個標準的節點：

<criterion>BBB</criterion> 
<criterion>CCC</criterion> 
<criterion>DDD</criterion> 

，使最終XML的結果是：

<root> 
    <criteria> 
     <criterion>BBB</criterion> 
     <criterion>CCC</criterion> 
     <criterion>DDD</criterion> 
    </criteria> 
</root> 

我已經嘗試過使用substring-before和substring-after來複制結構的前半部分，然後ju st複製下半部分（爲了填充兩個半部分之間的新節點），但似乎子字符串函數只識別節點標記之間的文本，而不是像我希望的那樣標記本身。 :(:(

任何其他解決辦法？

Answer 1

XSL不能代替任何，你能做的最好的就是要保留部分複製，再輸出要代替改變零件的零件你不想讓

---

例：

<?xml version="1.0" encoding="utf-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl" 
> 
    <xsl:output method="xml" indent="yes"/> 

    <!-- This is an identity template - it copies everything 
     that doesn't match another template --> 
    <xsl:template match="@* | node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@* | node()"/> 
     </xsl:copy> 
    </xsl:template> 

    <!-- This is the "other template". It says to use your BBB-DDD elements 
     instead of the AAA element --> 
    <xsl:template match="criterion[.='AAA']"> 
    <xsl:element name="criterion"> 
     <xsl:text>BBB</xsl:text> 
    </xsl:element> 
    <xsl:element name="criterion"> 
     <xsl:text>CCC</xsl:text> 
    </xsl:element> 
    <xsl:element name="criterion"> 
     <xsl:text>DDD</xsl:text> 
    </xsl:element> 
    </xsl:template> 
</xsl:stylesheet> 

---

模板匹配@* | node()匹配任何屬性或任何其他類型的節點。訣竅是模板匹配具有優先級。你可以認爲這條規則是「更具體的比賽勝利」。 任何東西將比「任何屬性或其他節點」更具體。這使得「身份」的匹配度非常低。

當它與是匹配時，它只是複製它在匹配屬性或節點內找到的任何節點。

您擁有的任何其他模板將具有更高的優先級。無論它們匹配什麼，它都是更具體的模板中的代碼，它將會起作用。例如，如果您只是簡單地刪除了criterion[.='AAA']模板中的所有內容，則會發現您完全複製了輸入，除了「AAA」元素。

Answer 2

下更比一的方式對皮膚一貓的一般規律

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml"/> 
    <xsl:template match="/"> 
     <xsl:apply-templates /> 
    </xsl:template> 
    <!-- 
     when you capture a node with the text 'AAA' 
      emit the BBB, CCC, DDD nodes 
    --> 
    <xsl:template match="criterion[text() = 'AAA']"> 
     <xsl:element name="criterion"> 
      <xsl:text>BBB</xsl:text> 
     </xsl:element> 
     <xsl:element name="criterion"> 
      <xsl:text>CCC</xsl:text> 
     </xsl:element> 
     <xsl:element name="criterion"> 
      <xsl:text>DDD</xsl:text> 
     </xsl:element> 
    </xsl:template> 
    <!-- identity template --> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 3

這是一個正確的解決方案，這可能是最短的之一：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output omit-xml-declaration="yes" indent="yes"/> 
<xsl:strip-space elements="*"/> 

<xsl:template match="node()|@*"> 
    <xsl:copy> 
    <xsl:apply-templates select="node()|@*"/> 
    </xsl:copy> 
</xsl:template> 

<xsl:template match="criterion[. = 'AAA']"> 
    <criterion>BBB</criterion> 
    <criterion>CCC</criterion> 
    <criterion>DDD</criterion> </xsl:template> 
</xsl:stylesheet> 

當這個變換所提供的XML文檔應用，有用結果產生：

<root> 
    <criteria> 
     <criterion>BBB</criterion> 
     <criterion>CCC</criterion> 
     <criterion>DDD</criterion> 
    </criteria> 
</root> 

請注意：

1. 使用該身份模板的。

2. 身份模板如何被特定模板重寫 - 僅適用於criterion元素，其字符串值爲'AAA'。