定位熄滅圖表區域

Question

當我運行下面的代碼

pMin = {-3, -3}; 
pMax = {3, 3}; 
range = {pMin, pMax}; 
Manipulate[ 
GraphicsGrid[ 
    { 
    {Graphics[Locator[p], PlotRange -> range]}, 
    {Graphics[Line[{{0, 0}, p}]]} 
    }, Frame -> All 
    ], 
{{p, {1, 1}}, Locator} 
] 

我希望定位器控制是第一張圖的範圍內的，而是它可以移動整個GraphicsGrid區域。我的代碼中有錯誤嗎？

我也試過

{{p, {1, 1}}, pMin, pMax, Locator} 

，而不是

{{p, {1, 1}}, Locator} 

但它的行爲完全錯誤的。

UPDATE

感謝大家，這是我最終的解決方案：

Manipulate[ 
distr1 = BinormalDistribution[p1, {1, 1}, \[Rho]1]; 
distr2 = BinormalDistribution[p2, {1, 1}, \[Rho]2]; 
Grid[ 
    { 
    {Graphics[{Locator[p1], Locator[p2]}, 
    PlotRange -> {{-5, 5}, {-5, 5}}]}, 
    {Plot3D[{PDF[distr1, {x, y}], PDF[distr2, {x, y}]}, {x, -5, 5}, {y, -5, 5}, PlotRange -> All]} 
    }], 
{{\[Rho]1, 0}, -0.9, 0.9}, {{\[Rho]2, 0}, -0.9, 0.9}, 
{{p1, {1, 1}}, Locator}, 
{{p2, {1, 1}}, Locator} 
] 

UPDATE

現在的問題是，我不能調整大小和旋轉較低的3d圖。有誰知道如何解決這個問題？ 我回到了兩個Slider2D對象的解決方案。

Answer 1

我不確定你想達到什麼目的。我看到了一些問題，但我不知道要解決什麼問題。也許你只是想要一個簡單的Slider2D建設？

DynamicModule[{p = {1, 1}}, 
Column@{Slider2D[Dynamic[p], {{-3, -3}, {3, 3}}, 
    ImageSize -> {200, 200}], 
    Graphics[Line[{{0, 0}, Dynamic[p]}], 
    PlotRange -> {{-3, 3}, {-3, 3}}, ImageSize -> {200, 200}]}] 

---

這是關於3D圖形旋轉更新的問題的答覆。

我相信大衛建議的LocatorPane是一種很好的方法來解決這個問題。我只是把一個通用的功能，因爲你的例子如果您檢查您會發現，GraphicsGrid返回一個圖形對象InputForm不會對數學7

DynamicModule[{pt = {{-1, 3}, {1, 1}}}, 
Column[{ 
    LocatorPane[Dynamic[pt], 
    Framed@Graphics[{}, PlotRange -> {{-5, 5}, {-5, 5}}]], 
    Dynamic@ 
    Plot3D[{x^2 pt[[1, 1]] + y^2 pt[[1, 2]], 
      -x^2 pt[[2, 1]] - y^2 pt[[2, 1]]}, 
     {x, -5, 5}, {y, -5, 5}] 
}] 
] 

Answer 2

運行。因此，定位器確實在整個圖像中移動。

GraphicsGrid[{{Graphics[Circle[]]}, {Graphics[Disk[]]}}] // InputForm 

如果你只是改變GraphicsGrid到網格，定位器將被限制在第一部分，但結果仍然看起來有點奇怪。你的PlotRange規範有點奇怪，它似乎不符合文檔中心指定的任何格式。也許你想要下面的東西。

Manipulate[ 
Grid[{ 
    {Graphics[Locator[p], Axes -> True, 
    PlotRange -> {{-3, 3}, {-3, 3}}]}, 
    {Graphics[Line[{{0, 0}, p}], Axes -> True, 
    PlotRange -> {{-3, 3}, {-3, 3}}]}}, 
    Frame -> All], 
{{p, {1, 1}}, Locator}] 

Answer 3

LocatorPane[]做了一個很好的限制定位器的區域。

這是Wizard先生使用的方法的變體。

Column[{ LocatorPane[Dynamic[pt3], 
    Framed@Graphics[{}, ImageSize -> 150, PlotRange -> 3]], 
    Framed@Graphics[{Line[{{-1, 0}, Dynamic@pt3}]}, ImageSize -> {150, 150}, 
    PlotRange -> 3]}] 

我會假設你想要的定位與大家分享它控制線的空間。事實上，要「附加」到該行。事實證明，這更容易實現。

Column[{LocatorPane[Dynamic[pt3],Framed@Graphics[{Line[{{-1, 0}, Dynamic@pt3}]}, 
ImageSize -> 150, PlotRange -> 3]]}]