將新的鍵值對添加到陣列列表

Question

我有2個ArrayList。一個是[[帳戶：價值，預算：價值]]，另一個是[[帳戶：價值，cYBudget：價值]]我想結束以下格式的列表：[[帳戶：價值，預算：價值，cYBudget：值]]

的數據的一個例子是：

budProp = [[ACCTCODE：6201，BUDGET：2500]，[ACCTCODE：7999，BUDGET：1500]

budCyExp = [[ACCTCODE：6201，cYBudget：1000]，[ACCTCODE：7999，cYBudget：2000]]

我想的結果：

[[ACCTC ODE：6201，BUDGET：2500，cYBudget：1000]，[ACCTCODE：7999，BUDGET：1500，cYBudget：2000]]

基本上我通過匹配ACCTCODE來「合併」兩個列表並確保每個列表包含ACCTCODE，BUDGET和cYBudget鍵/值對。 Groovy是否有一些方法可以做到這一點？

我正在使用Groovy 2.3.7

謝謝。

Answer 1

的方法GroovyCollections#transpose()可以從兩個列表生成對的列表：

groovy:000> [[1,2,3], [4,5,6]].transpose() 
===> [[1, 4], [2, 5], [3, 6]] 

如果你有在同一順序相同的帳戶代碼的兩個列表，你可以壓縮並行列表條目成對的地圖用轉置方法，然後合併各對的地圖：

[budProp, budCyExp].transpose().collect { it[0] + it[1] } 

以下是groovysh細分，以便可以看到分別調換的結果如下步驟：

groovy:000> budProp = [[ACCTCODE:6201, BUDGET:2500], [ACCTCODE:7999, BUDGET:1500]] 
===> [[ACCTCODE:6201, BUDGET:2500], [ACCTCODE:7999, BUDGET:1500]] 
groovy:000> budCyExp = [[ACCTCODE:6201,cYBudget:1000],[ACCTCODE:7999,cYBudget: 2000]] 
===> [[ACCTCODE:6201, cYBudget:1000], [ACCTCODE:7999, cYBudget:2000]] 
groovy:000> [budProp, budCyExp].transpose() 
===> [[[ACCTCODE:6201, BUDGET:2500], [ACCTCODE:6201, cYBudget:1000]], [[ACCTCODE:7999, BUDGET:1500], [ACCTCODE:7999, cYBudget:2000]]] 
groovy:000> _.collect { it[0] + it[1] } 
===> [[ACCTCODE:6201, BUDGET:2500, cYBudget:1000], [ACCTCODE:7999, BUDGET:1500, cYBudget:2000]] 

在現實生活中，我會猶豫不決，除非我100％確定平行列表完美排列（一個列表中的每個帳戶代碼都在另一個列表中），否則我會做類似的事情：

groovy:000> budMap = budProp.inject([:]) { m, e -> m[e['ACCTCODE']] = e['BUDGET']; m } 
===> [6201:2500, 7999:1500] 
groovy:000> cyMap = budCyExp.inject([:]) { m, e -> m[e['ACCTCODE']] = e['cYBudget']; m } 
===> [6201:1000, 7999:2000] 
groovy:000> (budMap.keySet() + cyMap.keySet()).collect { [ACCTCODE: it, BUDGET: budMap[it], cYBudget: cyMap[it] ] } 
===> [[ACCTCODE:6201, BUDGET:2500, cYBudget:1000], [ACCTCODE:7999, BUDGET:1500, 
cYBudget:2000]] 

這並不短，但它處理的情況是一個列表中的賬戶沒有在另一個列表中表示。

Answer 2

在名單不排隊完美的情況下，這將是更適合使用Groovy的Iterable.groupBy(Closure)方法：

def budProp = [[ACCTCODE:6201, BUDGET:2500], [ACCTCODE:7999, BUDGET:1500]] 
def budCyExp = [[ACCTCODE:7999,cYBudget: 2000], [ACCTCODE:6201,cYBudget:1000]] 

def budMaster = (budProp + budCyExp) 
println budMaster 
//[[ACCTCODE:6201, BUDGET:2500], [ACCTCODE:7999, BUDGET:1500], [ACCTCODE:7999, cYBudget:2000], [ACCTCODE:6201, cYBudget:1000]] 

def budMappedAcct = budMaster.groupBy { it.ACCTCODE } 
println budMappedAcct 
// [6201:[[ACCTCODE:6201, BUDGET:2500], [ACCTCODE:6201, cYBudget:1000]], 7999:[[ACCTCODE:7999, BUDGET:1500], [ACCTCODE:7999, cYBudget:2000]]] 

def budMapList = budMappedAcct.collect { code, mapList -> mapList.sum() } 
println budMapList 
// [[ACCTCODE:6201, BUDGET:2500, cYBudget:1000], [ACCTCODE:7999, BUDGET:1500, cYBudget:2000]] 

這工作秩序和不匹配的列表超出太多，只要所有原始地圖都有ACCTCODE。如果需要，可以將此解決方案精簡爲一行：

def budMapList = (budProp + budCyExp).groupBy { it.ACCTCODE }.collect { code, mapList -> mapList.sum() }