找到列中的第一個元音並將其顯示在下一列

Question

我想要做的事情非常基本。我想遍歷整列「I」，然後在「M」列中顯示這個元音。但我想遍歷該列中的所有1000多行。這是我到目前爲止，但我得到一個引用基於對象的錯誤。

Private Sub Form_Load() 
    Dim mystring As String, i As Long, asciinum As String, f As Long 

    For f = 1 To Rows.Count 
     Rows(f, "I") = mystring 
     For i = 1 To Len(mystring) 
      asciinum = LCase(Mid(mystring, i, 1)) 
      If asciinum = "a" Or asciinum = "e" Or asciinum = "i" Or asciinum = "o" Or asciinum = "u" Then 
       Rows(f, "M") = "First Vowel " + asciinum 
       Exit For 
      End If 
     Next 
     Exit For 
    Next 
End Sub 

可能是陣列和For ... Loop的錯誤？

Answer 1

你有賦值和向後需要使用Cells代替Rows。

Option Explicit 

Private Sub Form_Load() 
    Dim mystring As String, i As Long, asciinum As String, f As Long 

    For f = 1 To Rows.Count 
     mystring = Cells(f, "I").Value2 
     For i = 1 To Len(mystring) 
      asciinum = LCase(Mid(mystring, i, 1)) 
      If asciinum = "a" Or asciinum = "e" Or asciinum = "i" Or asciinum = "o" Or asciinum = "u" Then 
       Cells(f, "M") = "First Vowel " + asciinum 
       Exit For 
      End If 
     Next 
     Exit For 
    Next 
End Sub 

這應該在ActiveSheet工作，但你應該開始進入使用的定義父表的做法，只能使用同值的單元格在他們的不降反升的循環一路到工作表的底部。

Option Explicit 

Private Sub Form_Load() 
    Dim mystring As String, i As Long, asciinum As String, f As Long 

    With Worksheets("sheet1") 
     For f = 1 To .Cells(.Rows.Count, "I").End(xlUp).Row 
      mystring = .Cells(f, "I").Value2 
      For i = 1 To Len(mystring) 
       asciinum = LCase(Mid(mystring, i, 1)) 
       If asciinum = "a" Or asciinum = "e" Or asciinum = "i" Or asciinum = "o" Or asciinum = "u" Then 
        .Cells(f, "M") = "First Vowel " + asciinum 
        Exit For 
       End If 
      Next i 
     Next f 
    End With 
End Sub 

我也刪除了第二個Exit For，以便它繼續外部循環。

Answer 2

你不需要宏找到它，公式會做 - 假設A1是你檢查電池，=MID(A1,FIND({"a","e","i","o","u"},A1),1)會做

Answer 3

最後，我去了正則表達式的太強大的黑暗藝術：

Private Sub Form_Load() 

    'Requires reference to "Microsoft VBScript Regular Expression 5.5" 

    Dim mystring As String, i As Long, asciinum As String, f As Long 
    Dim regFindVowels As New RegExp 
    Dim FoundVowels As Variant 
    regFindVowels.Pattern = "[AEIOUaeiou]" 
    regFindVowels.Global = True 

    With Worksheets("Sheet 1") ' change this to your sheetname 
     For f = 1 To .Cells(.Rows.Count, "I").End(xlUp).Row 
      Set FoundVowels = regFindVowels.Execute(.Cells(f, "I").Value2) 
      If FoundVowels.Count > 0 Then .Cells(f, "M") = "First Vowel " + FoundVowels(0) ' (0) is first, (1) is second etc. 
     Next 
    End With 

End Sub