當用戶激活另一個程序時卸載用戶窗體

Question

我有一個用戶窗體，當用戶從Excel更改爲另一個程序時，我想關閉用戶窗體。 我曾嘗試使用ThisWorkbook中的工作表關閉事件，但它沒有執行此技巧。

Private Sub Workbook_SheetDeactivate(ByVal Sh As Object) 

Unload UserForm1 

End Sub 

Answer 1

如何像這樣

Declare PtrSafe Function GetForegroundWindow Lib "user32.dll"() As LongPtr 
Declare PtrSafe Function GetActiveWindow Lib "user32.dll"() As LongPtr 

Sub test() 
Dim wbHwnd As LongPtr 
Dim fHwnd As LongPtr 
Dim aHwnd As LongPtr 

    'replace with timer class that ticks 
    Application.OnTime Now + TimeValue("00:00:10"), "test", , True 

    wbHwnd = Application.hWnd 
    fHwnd = GetForegroundWindow 
    aHwnd = GetActiveWindow 

    If wbHwnd <> fHwnd Then 
     Debug.Print "Lost focus" 
    Else 
     Debug.Print "Has focus" 
    End If 


End Sub 

這只是獲取當前應用程序的HWND，並確定它的前臺窗口。而不是使用Application.Ontime，可能更好的方法是使用按設定的時間間隔滴答的計時器類。

另外，您可以更具體地使用Hwnd而不是應用程序。並且如果您保持Ontime事件，請記住在工作簿關閉或類似時禁用定時器。

編輯：

假設用戶窗體具有獨特的標題，你可以使用用戶窗體標題

Declare PtrSafe Function GetForegroundWindow Lib "User32.dll"() As LongPtr 
Declare PtrSafe Function GetActiveWindow Lib "User32.dll"() As LongPtr 
Private Declare PtrSafe Function FindWindow Lib "User32.dll" Alias "FindWindowA" _ 
    (ByVal ClassName As String, ByVal WindowName As String) As LongPtr 



Sub test() 
Dim wbHwnd As LongPtr 
Dim fHwnd As LongPtr 
Dim aHwnd As LongPtr 
Dim ufHwnd As LongPtr 

    'replace with timer class that ticks 
    Application.OnTime Now + TimeValue("00:00:10"), "test", , True 

    wbHwnd = Application.hWnd 
    fHwnd = GetForegroundWindow 
    aHwnd = GetActiveWindow 
    ufHwnd = FindWindow("ThunderDFrame", UserForm1.Caption) 

    If wbHwnd <> fHwnd Then 
     Debug.Print "Lost focus " & wbHwnd & " " & fHwnd & " " & aHwnd & " " & ufHwnd 
    Else 
     Debug.Print "Has focus " & wbHwnd & " " & fHwnd & " " & aHwnd & " " & ufHwnd 
    End If 


End Sub