刪除僅包含特定文件（批處理文件）的空目錄和目錄

Question

我需要一個批處理文件，它刪除所有僅包含特定文件（.svn）的空目錄和目錄。非常感謝您的幫助。

例子：

Folder1      -- folder conatins subfolders with some files, not remove 
    Folder2     -- empty folder, folder should be deleted 
    Folder3     -- folder contains only .svn, folder should be deleted 
      .svn 
    Folder4     -- folder contains subfolder with file, not remove 
      Folder41   -- folder contains some file, not remove 
       somefile.dat 
    Folder5     -- folder contains some file, not remove 
      .svn 
      somefile.dat 
    Folder6     -- folder contains empty subfolders, folder should be deleted 
      Folder61   -- folder contains only specific file, folder should be deleted 
       .svn 

結果：

Folder1 
    Folder4  
      Folder41 
       somefile.dat 
    Folder5 
      .svn 
      somefile.dat 

Answer 1

我是在多麼少的代碼這需要感到驚訝。最大的竅門是在DIR /B /S /AD的輸出上使用SORT /R，以便您可以在處理文件夾層次結構的父節點之前處理子節點。

我已經很快測試了代碼，但請以安全的方式測試自己。

此第一個版本假設爲".SVN"是完整的文件名。

@echo off 
setlocal disableDelayedExpansion 
for /f "eol=: delims=" %%A in ('dir /b /s /ad ^| sort /r') do (
    dir /b "%%A" | findstr /livx ".svn" >nul || rd /s /q "%%A" 
) 

第2版本是在你的意思"*.SVN"情況下，僅略作修改。只有一個FINDSTR選項被更改。

@echo off 
setlocal disableDelayedExpansion 
for /f "eol=: delims=" %%A in ('dir /b /s /ad ^| sort /r') do (
    dir /b "%%A" | findstr /live ".svn" >nul || rd /s /q "%%A" 
) 

更新：2012年11月6日

我只是意識到上述溶液（S）可以，如果一個非空文件夾命名爲.SVN被擊敗。該代碼應刪除空的文件夾或只包含名爲.SVN的文件。如果文件夾包含名爲.SVN的非空文件夾，則不應刪除該文件夾。

下面是第一個解決方案修復：

@echo off 
setlocal disableDelayedExpansion 
for /f "eol=: delims=" %%A in ('dir /b /s /ad ^| sort /r') do (
    dir /b "%%A"|findstr /livx ".svn" >nul||>nul 2>&1 dir /b /ad .svn||rd /s /q "%%A" 
) 

這裏是第二個解決方案

@echo off 
setlocal disableDelayedExpansion 
for /f "eol=: delims=" %%A in ('dir /b /s /ad ^| sort /r') do (
    dir /b "%%A"|findstr /live ".svn" >nul||>nul 2>&1 dir /b /ad *.svn||rd /s /q "%%A" 
)