將簡單腳本從actionscript2轉換爲actionscript3

Question

我是as3的初學者，並且一直遵循簡單的Flash草圖板腳本，這裏是鏈接>http://www.sitepoint.com/create-flash-sketchpad/。它的編碼爲as2，但我想將代碼轉換爲as3.I一直試圖將它們轉換爲as3，但我似乎無法使其工作。我非常感謝有人可以幫助我。

createEmptyMovieClip("Line",1); 
Line.lineStyle(3,0x000000,300); 

onMouseDown = function() { 
    Line.moveTo(_xmouse, _ymouse); 
    onMouseMove = function() { 
     Line.lineTo(_xmouse, _ymouse); 
    } 
} 

onMouseUp=function() { 
    onMouseMove=null; 
} 

Answer 1

這將在AS3給：

var Line:Sprite = new Sprite(); 
addChild(Line); 
Line.graphics.lineStyle(3, 0x000000, 1); 

stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler); 
addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler); 

function mouseDownHandler(e:MouseEvent):void { 
    Line.graphics.moveTo(e.stageX, e.stageY); 
    stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler); 
} 

function mouseMoveHandler(e:MouseEvent):void { 
    Line.graphics.lineTo(e.stageX, e.stageY); 
} 

function mouseUpHandler(e:MouseEvent):void { 
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler); 
} 

Answer 2

我決定創建一個完整的工作示例，這樣你就可以理解它是如何工作的;

package { 
    import flash.display.Shape; 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 

    /** 
    * ... 
    * @author Martyn 
    */ 
    public class Main extends Sprite { 

     public var draw:Shape = new Shape(); 

     public function Main():void { 
      if (stage) init(); 
      else addEventListener(Event.ADDED_TO_STAGE, init); 
     } 

     private function init(e:Event = null):void { 
      removeEventListener(Event.ADDED_TO_STAGE, init); 
      stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); 
      stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp); 

      trace("init"); 
      addChild(draw); 
      draw.graphics.lineStyle(3, 0x000000, 300); 

     } 
     private function onMouseDown(e:MouseEvent):void 
     { 
      stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
      draw.graphics.moveTo(mouseX, mouseY); 
      trace("onMouseDown"); 
     } 

     private function onMouseUp(e:MouseEvent):void 
     { 
      stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
      trace("onMouseUp"); 
     } 

     private function onMouseMove(e:MouseEvent):void 
     { 
      draw.graphics.lineTo(mouseX, mouseY); 
      trace("onMouseMove"); 
     } 

    } 

} 

希望這會有所幫助。