從批處理文件中讀取文本文件，然後將文本傳遞給另一個功能

Question

希望有人可以提供幫助。我試圖通過使用谷歌搜索這個網站，但我要麼得到錯誤的關鍵字，否則我是第一個遇到這個問題（不太可能）的人。

我想從Windows批處理文件中的文本文件中讀取域列表，我將在下面發佈這些文件。對於每個我試圖將結果寫入文件的人。我已經看過「for/f」的各種用法，但無法弄清楚爲了讓這條線路正常工作我需要做些什麼。下面的代碼：

@setlocal 
@echo off 
for /F "tokens=1" %%D in (c:\whois-for-win32\domainlist.txt) do call :reportit 
endlocal 
goto :eof 

:reportit 
setlocal 
echo " Retrieving details for: %%D" 
echo " WHOIS:  %%D" >> c:\whois-for-win32\results\domainlisting.txt 
echo "=============================================================" >> c:\whois-for-win32\results\domainlisting.txt 
whois %%D >> c:\whois-for-win32\results\domainlisting.txt 
timeout 8 
endlocal 

現在，假設數據文件提到只有一個域，每行上市。顯然，我這樣做的原因是我們有相當多的域來檢查。

你的想法和想法都非常感謝！

Answer 1

如果使用FOR-Loops，則該參數僅在for循環的上下文中可見。
在你的函數中不能以%% D的形式訪問。

但你可以通過它們作爲參數
在這種情況下，我使用「%%〜D」，因爲%%〜D刪除封閉的引號，如果有一些，然後我把它括在引號中以確保該內容將僅作爲一個參數提供。

在函數中，可以通過％1訪問傳遞的參數，但要刪除我使用％〜1的引號。

@echo off 
setlocal 
for /F "tokens=* EOL=# delims=" %%D in (c:\whois-for-win32\domainlist.txt) do call :reportit "%%~D" 
endlocal 
goto :eof 

:reportit 
setlocal 
set "domain=%~1" 
echo " Retrieving details for: %domain%" 
echo " WHOIS:  %domain%" >> c:\whois-for-win32\results\domainlisting.txt 
echo "=============================================================" >> c:\whois-for-win32\results\domainlisting.txt 
whois %domain% >> c:\whois-for-win32\results\domainlisting.txt 
timeout 8 
endlocal 
exit /b