模式匹配中的OCaml多態變體

Question

我正在通過AST變換增長一種小型編程語言。也就是說，從虛擬機開始，慢慢添加一些幫助程序員的層。

由於每一層都知道如何將其新的類型，我做了這樣的事情：

module AST0 = struct 

    type t = [ 
    | `Halt 
    | `In 
    | `Out 
    | `Add of (int * int * int) 
    | `Sub of (int * int * int) 
    ] 

    let lower (ast : t list) = ast 
end 

module AST1 = struct 
    type t = [ 
    AST0.t 

    | `Inc of int 
    | `Dec of int 
    | `Cmp of (int * int * int) 
    ] 

    let lower (ast : t list) = 
    let lower_one = function 
     | `Inc a -> [`Add (a, a, `Imm 1)] 
     | `Dec a -> [`Sub (a, a, `Imm 1)] 
     | `Cmp (a, b) -> [`Sub (13, a, b)] 
     | (x : AST0.t) -> AST0.lower [x]  (* <--- problem line *) 
    in 
    List.concat @@ List.map lower_one ast 
end 

不幸的是我得到的錯誤：

File "stackoverflow.ml", line 28, characters 8-20: 
Error: This pattern matches values of type AST0.t 
     but a pattern was expected which matches values of type 
     [? `Cmp of 'a * 'b | `Dec of 'c | `Inc of 'd ] 
     The first variant type does not allow tag(s) `Cmp, `Dec, `Inc 

我想，因爲編譯器是智能足以注意到我沒有在任意匹配的情況下處理XY和Z變體，它可以說明x在AST1.lower將永遠不會是Cmp或Inc或Dec之一。這似乎並非如此。

我誤解了OCaml的類型系統嗎？我錯過了明顯的東西嗎？這是一種愚蠢的做法嗎？

Answer 1

您不能在本地限制案例模式的類型。類型約束: AST0.t也強制其他模式的類型爲AST0.t。這就是爲什麼你的代碼不輸入檢查; `Inc不包括在AST0.t中。

然而，OCaml中有一個整潔的功能正是爲了你想要做的。 使用#AST0.t模式別名，而不是類型約束。詳情請參見https://caml.inria.fr/pub/docs/manual-ocaml/lablexamples.html#sec46：

(* I fixed several other trivial typing problems *) 
    let lower (ast : t list) = 
    let lower_one = function 
     | `Inc a -> [`Add (a, a, 1)] 
     | `Dec a -> [`Sub (a, a, 1)] 
     | `Cmp (a, b, c) -> [`Sub (13, a, b)] 
     | #AST0.t as x -> AST0.lower [x]  (* <--- problem line *) 
    in 
    List.concat @@ List.map lower_one ast 

#AST0.t as x不僅是(`Halt | `In | `Out | `And _ | `Sub _ as x)的縮寫，也改變了x在->右側從[> AST1.t]到[> AST0.t]類型。你可以在那裏用它作爲AST0.t。