批處理腳本替換文件第7行中的文本？

Question

我有一個文件，第7行聲明的變量爲 VERSION = 6.0.196.0。我需要編輯這行作爲VERSION = 6.0.200.0

而第15行作爲MANIFEST_BUILD => 196。這應該改爲MANIFEST_BUILD => 200。 如何做到這一點？

Answer 1

此答案中的所有解決方案僅使用Windows XP及更高版本的本機命令。

1）這是迄今爲止速度最快的原生批量解決方案成爲可能，但它擁有最限制

• 沒有在文件中的第15行的長度可以超過1021個字節
• 所有的前15行必須以<carriageReturn><lineFeed>（Windows風格）終止，而不是<lineFeed>（unix風格）。
• 沒有第一15行的可與控制字符（當然比行終止其他）結束

沒有爲XP和Windows 7一個附加的限制：該文件的最後行必須以<lineFeed>結束。由於FINDSTR中的錯誤，如果最後一行不以<linefeed>結尾，腳本將無限期掛起。有關更多信息，請參見What are the undocumented features and limitations of the Windows FINDSTR command?。

@echo off 
setlocal enableDelayedExpansion 
set "file=test.txt" 

REM redirect input from your file and output to a new file 
<"%file%" >"%file%.new" (

    REM preserve lines 1-6 
    for /l %%N in (1 1 6) do (
    set "ln=" 
    set /p "ln=" 
    echo(!ln! 
) 

    REM replace the next line (7) 
    set /p "ln=" 
    echo VERSION=6.0.196.0 

    REM preserve lines 8-14 
    for /l %%N in (8 1 14) do (
    set "ln=" 
    set /p "ln=" 
    echo(!ln! 
) 

    REM replace the next line (15) 
    set /p "ln=" 
    REM The > below must be escaped 
    echo MANIFEST_BUILD =^>200 

    REM preserve the remaining lines 
    findstr "^" 

) 

REM replace your original file with the new file 
>nul move /y "%file%.new" "%file%" 

2）下一個選項要慢得多，但限制要少得多。

• 無線可以比〜8191個字節
• 無線可以與:

此外開始，在輸出所有行將由<carriageReturn><lineFeed>終止，無論什麼類型的終止子的使用原始文件。

@echo off 
setlocal disableDelayedExpansion 
set "file=test.txt" 

>"%file%.new" (
    for /f "tokens=1* delims=:" %%A in ('findstr /n "^" "%file%"') do (
    if %%A==7 (
     echo VERSION=6.0.196.0 
    ) else if %%A==15 (
     echo MANIFEST_BUILD =^>200 
    ) else echo(%%B 
) 
) 
move /y "%file%.new" "%file%" 

3），此選項是幾乎相同的選項2，但它允許線以開始:。它比選項2更慢）。

@echo off 
setlocal disableDelayedExpansion 
set "file=test.txt" 

>"%file%.new" (
    for /f "delims=" %%A in ('findstr /n "^" "%file%"') do (
    for /f "delims=:" %%B in ("%%A") do (
     if %%B==7 (
      echo VERSION=6.0.196.0 
    ) else if %%B==15 (
      echo MANIFEST_BUILD =^>200 
    ) else (
      set "ln=%%A" 
      setlocal enableDelayedExpansion 
      echo(!ln:*:=! 
      endlocal 
    ) 
    ) 
) 
) 
move /y "%file%.new" "%file%" 

4）這最後一個選項是迄今爲止最強大的。它使用我編寫的可用於處理文本文件的混合JScript/Batch實用程序腳本。該腳本仍然只使用所有現代Windows平臺（XP以上版本）原生的命令。

該選項比選項1慢，但它可以在合理的時間內處理非常大的文件。它比選項2和3快得多，對於大型文件而言太慢了。

該選項還保留原始文件中存在的行結束符。

我不知道此選項的任何限制。

這是依賴於我的REPL的腳本。BAT實用程序

@echo off 
set "file=test.txt" 
findstr /n "^" "%file%" | repl "^(7:.*)" "VERSION=6.0.196.0" m | repl "^(15:.*)" "MANIFEST_BUILD =>200" m | repl "^\d*:" "" m>"%file%.new" 
>nul move /y "%file%.new" "%file%" 

這裏是上述腳本所需的REPL.BAT實用程序。應將REPL.BAT放置在您的PATH的Sowewhere中。完整的文檔嵌入在腳本中。

@if (@X)==(@Y) @end /* Harmless hybrid line that begins a JScript comment 

::************ Documentation *********** 
::: 
:::REPL Search Replace [Options [SourceVar]] 
:::REPL /? 
::: 
::: Performs a global search and replace operation on each line of input from 
::: stdin and prints the result to stdout. 
::: 
::: Each parameter may be optionally enclosed by double quotes. The double 
::: quotes are not considered part of the argument. The quotes are required 
::: if the parameter contains a batch token delimiter like space, tab, comma, 
::: semicolon. The quotes should also be used if the argument contains a 
::: batch special character like &, |, etc. so that the special character 
::: does not need to be escaped with ^. 
::: 
::: If called with a single argument of /? then prints help documentation 
::: to stdout. 
::: 
::: Search - By default this is a case sensitive JScript (ECMA) regular 
:::   expression expressed as a string. 
::: 
:::   JScript syntax documentation is available at 
:::   http://msdn.microsoft.com/en-us/library/ae5bf541(v=vs.80).aspx 
::: 
::: Replace - By default this is the string to be used as a replacement for 
:::   each found search expression. Full support is provided for 
:::   substituion patterns available to the JScript replace method. 
:::   A $ literal can be escaped as $$. An empty replacement string 
:::   must be represented as "". 
::: 
:::   Replace substitution pattern syntax is documented at 
:::   http://msdn.microsoft.com/en-US/library/efy6s3e6(v=vs.80).aspx 
::: 
::: Options - An optional string of characters used to alter the behavior 
:::   of REPL. The option characters are case insensitive, and may 
:::   appear in any order. 
::: 
:::   I - Makes the search case-insensitive. 
::: 
:::   L - The Search is treated as a string literal instead of a 
:::    regular expression. Also, all $ found in Replace are 
:::    treated as $ literals. 
::: 
:::   E - Search and Replace represent the name of environment 
:::    variables that contain the respective values. An undefined 
:::    variable is treated as an empty string. 
::: 
:::   M - Multi-line mode. The entire contents of stdin is read and 
:::    processed in one pass instead of line by line.^anchors 
:::    the beginning of a line and $ anchors the end of a line. 
::: 
:::   X - Enables extended substitution pattern syntax with support 
:::    for the following escape sequences: 
::: 
:::    \\  - Backslash 
:::    \b  - Backspace 
:::    \f  - Formfeed 
:::    \n  - Newline 
:::    \r  - Carriage Return 
:::    \t  - Horizontal Tab 
:::    \v  - Vertical Tab 
:::    \xnn - Ascii (Latin 1) character expressed as 2 hex digits 
:::    \unnnn - Unicode character expressed as 4 hex digits 
::: 
:::    Escape sequences are supported even when the L option is used. 
::: 
:::   S - The source is read from an environment variable instead of 
:::    from stdin. The name of the source environment variable is 
:::    specified in the next argument after the option string. 
::: 

::************ Batch portion *********** 
@echo off 
if .%2 equ . (
    if "%~1" equ "/?" (
    findstr "^:::" "%~f0" | cscript //E:JScript //nologo "%~f0" "^:::" "" 
    exit /b 0 
) else (
    call :err "Insufficient arguments" 
    exit /b 1 
) 
) 
echo(%~3|findstr /i "[^SMILEX]" >nul && (
    call :err "Invalid option(s)" 
    exit /b 1 
) 
cscript //E:JScript //nologo "%~f0" %* 
exit /b 0 

:err 
>&2 echo ERROR: %~1. Use REPL /? to get help. 
exit /b 

************* JScript portion **********/ 
var env=WScript.CreateObject("WScript.Shell").Environment("Process"); 
var args=WScript.Arguments; 
var search=args.Item(0); 
var replace=args.Item(1); 
var options="g"; 
if (args.length>2) { 
    options+=args.Item(2).toLowerCase(); 
} 
var multi=(options.indexOf("m")>=0); 
var srcVar=(options.indexOf("s")>=0); 
if (srcVar) { 
    options=options.replace(/s/g,""); 
} 
if (options.indexOf("e")>=0) { 
    options=options.replace(/e/g,""); 
    search=env(search); 
    replace=env(replace); 
} 
if (options.indexOf("l")>=0) { 
    options=options.replace(/l/g,""); 
    search=search.replace(/([.^$*+?()[{\\|])/g,"\\$1"); 
    replace=replace.replace(/\$/g,"$$$$"); 
} 
if (options.indexOf("x")>=0) { 
    options=options.replace(/x/g,""); 
    replace=replace.replace(/\\\\/g,"\\B"); 
    replace=replace.replace(/\\b/g,"\b"); 
    replace=replace.replace(/\\f/g,"\f"); 
    replace=replace.replace(/\\n/g,"\n"); 
    replace=replace.replace(/\\r/g,"\r"); 
    replace=replace.replace(/\\t/g,"\t"); 
    replace=replace.replace(/\\v/g,"\v"); 
    replace=replace.replace(/\\x[0-9a-fA-F]{2}|\\u[0-9a-fA-F]{4}/g, 
    function($0,$1,$2){ 
     return String.fromCharCode(parseInt("0x"+$0.substring(2))); 
    } 
); 
    replace=replace.replace(/\\B/g,"\\"); 
} 
var search=new RegExp(search,options); 

if (srcVar) { 
    WScript.Stdout.Write(env(args.Item(3)).replace(search,replace)); 
} else { 
    while (!WScript.StdIn.AtEndOfStream) { 
    if (multi) { 
     WScript.Stdout.Write(WScript.StdIn.ReadAll().replace(search,replace)); 
    } else { 
     WScript.Stdout.WriteLine(WScript.StdIn.ReadLine().replace(search,replace)); 
    } 
    } 
}