EXCEL VBA如何使用函數和分割從字符串中提取整數

Question

我正在處理一段代碼以從其標記名中提取管道的標稱大小。例如：L-P-50-00XX-0000-000。 。50將是它的標稱尺寸（2" ），我想提取我知道我能做到這一點是這樣的：

TagnameArray() = Split("L-P-50-00XX-0000-000", "-") 
DNSize = TagnameArray(2) 

但我想這是一個功能，因爲它是一小部分我整個宏觀，我並不需要它爲所有我的工作只是這一個植物我當前的代碼是：

Sub WBDA_XXX() 
Dim a As Range, b As Range 
Dim TagnameArray() As String 
Dim DNMaat As String 
Dim DN As String 

Set a = Selection 

For Each b In a.Rows 
    IntRow = b.Row 
    TagnameArray() = Split(Cells(IntRow, 2).Value, "-") 
    DN = DNMaat(IntRow, TagnameArray()) 
    Cells(IntRow, 3).Value = DN 
Next b 
End Sub 



Function DNMaat(IntRow As Integer, TagnameArray() As String) As Integer 
    For i = LBound(TagnameArray()) To UBound(TagnameArray()) 
     If IsNumeric(TagnameArray(i)) = True Then 
      DNMaat = TagnameArray(i) 
      Exit For 
     End If 
    Next i 
End Function 

但是這個代碼給了我一個矩陣預期的錯誤，我不知道如何我還想在進一步的計算中使用名義大小，所以在從標記名中提取它之後，必須將它轉換爲整數。有沒有人看到我在代碼中犯了錯誤？

Answer 1

這很容易做到分裂，並從'喜歡'評估一點幫助。

上「喜歡」一點背景 - 將基於輸入變量是否一個給定的模式匹配返回TRUE或FALSE。 [A-Z]表示它可以是A和Z之間的任何大寫字母，而#表示任意數字。

代碼：

' Function declared to return variant strictly for returning a Null string or a Long 
Public Function PipeSize(ByVal TagName As String) As Variant 
    ' If TagName doesn't meet the tag formatting requirements, return a null string 
    If Not TagName Like "[A-Z]-[A-Z]-##-##[A-Z]-####-###" Then 
     PipeSize = vbNullString 
     Exit Function 
    End If 

    ' This will hold our split pipecodes 
    Dim PipeCodes As Variant 
    PipeCodes = Split(TagName, "-") 

    ' Return the code in position 2 (Split returns a 0 based array by default) 
    PipeSize = PipeCodes(2) 
End Function 

您將要考慮改變根據您的需求函數的返回類型。如果輸入標籤不匹配模式，它將返回一個空字符串，否則返回一個長（數字）。如果需要，您可以將其更改爲返回字符串，或者您可以編寫第二個函數來將該數字解釋爲長度。

下面是您的代碼的重構版本，它只查找第一個數字標記。我清理了一下你的代碼，我想我也發現了這個bug。你被宣佈DNMAAT爲String，但也要求它作爲一個Function。這可能會導致您的陣列預期錯誤。

下面的代碼：

' Don't use underscores '_' in names. These hold special value in VBA. 
Sub WBDAXXX() 
    Dim a As Range, b As Range 
    Dim IntRow As Long 

    Set a = Selection 

    For Each b In a.Rows 
     IntRow = b.Row 
     ' No need to a middleman here. I directly pass the split values 
     ' since the middleman was only used for the function. Same goes for cutting DN. 
     ' Also, be sure to qualify these 'Cells' ranges. Relying on implicit 
     ' Activesheet is dangerous and unpredictable. 
     Cells(IntRow, 3).value = DNMaat(Split(Cells(IntRow, 2).value, "-")) 

    Next b 
End Sub 

' By telling the function to expect a normal variant, we can input any 
' value we like. This can be dangerous if you dont anticipate the errors 
' caused by Variants. Thus, I check for Arrayness on the first line and 
' exit the function if an input value will cause an issue. 
Function DNMaat(TagnameArray As Variant) As Long 
    If Not IsArray(TagnameArray) Then Exit Function 

    Dim i As Long 
    For i = LBound(TagnameArray) To UBound(TagnameArray) 
     If IsNumeric(TagnameArray(i)) = True Then 
      DNMaat = TagnameArray(i) 
      Exit Function 
     End If 
    Next i 
End Function 

Answer 2

錯誤matrix expected由編譯器拋出，因爲你已經定義DNMaat兩次：作爲一個功能一旦作爲字符串變量和一次。將定義作爲變量移除。

另一件事：你的函數會返回一個整數，但是你把它分配給一個字符串（這個字符串用來只是把結果寫入到一個細胞）。擺脫可變DN，並直接分配給它：

Cells(IntRow, 3).Value = DNMaat(IntRow, TagnameArray()) 

加上全球建議使用option explicit強制所有使用的變量的定義，定義一個變量總是抱着一個行/列數long而不是integer