Ecto沙盒使用檢出連接現有過程

Question

我有一個菲尼克斯測試應用程序與產品模式。 我有一個由主應用程序管理器啓動的GenServer，它獲取帶有handle_call的產品列表。

def handle_call(:get_products, _from, _state) 
    products = Repo.all(Product) 
    {:reply, products, products} 
end 

現在我想爲這個GenServer編寫一個測試。

我試圖做這樣的事情在

setup do 
    pid = Process.whereis(MyGenServer) 
    Ecto.Adapters.SQL.Sandbox.allow(Repo, self(), pid) 
    ProductFactory.insert_list(3, :product) # using ExMachina for factories 
end 

的3個產品獲得創建的測試，我可以與Repo.all（產品）的測試找到他們，但是運行MyGenServer.get_products()將返回一個空陣列。

我是沒有得到任何錯誤，但只是返回一個空數組，就好像沒有產品存在一樣。

有什麼方法可以讓現有的PID使用結帳沙箱連接，並在GenServer進程中檢索我的產品？

PS。我設法通過在測試設置中重新啓動GenServer進程來運行測試，但我想知道是否有更「優雅」的方式來解決這個問題。

setup do 
    Supervisor.terminate_child(MyApp.Supervisor, MyGenServer) 
    Supervisor.restart_child(MyApp.Supervisor, MyGenServer) 
    ProductFactory.insert_list(3, :product) 
end 

感謝

Answer 1

下面是工作與GenServer開始在應用程序管理器，使用:shared模式數據庫交互的最小鳳凰應用。

應用模塊：

defmodule TestGenServers.Application do 
    use Application 

    def start(_type, _args) do 
    import Supervisor.Spec 

    children = [ 
     supervisor(TestGenServers.Repo, []), 
     supervisor(TestGenServers.Web.Endpoint, []), 
     worker(TestGenServers.MyServer, []) 
    ] 

    opts = [strategy: :one_for_one, name: TestGenServers.Supervisor] 
    Supervisor.start_link(children, opts) 
    end 
end 

產品模塊：

defmodule TestGenServers.Model.Product do 
    use Ecto.Schema 
    import Ecto.Changeset 
    alias TestGenServers.Model.Product 


    schema "model_products" do 
    field :name, :string 

    timestamps() 
    end 

    @doc false 
    def changeset(%Product{} = product, attrs) do 
    product 
    |> cast(attrs, [:name]) 
    |> validate_required([:name]) 
    end 
end 

GenServer模塊：

defmodule TestGenServers.MyServer do 
    use GenServer 
    alias TestGenServers.Repo 

    def start_link() do 
    GenServer.start_link(__MODULE__, nil, name: __MODULE__) 
    end 

    def handle_call({:get_product, id}, _caller, state) do 
    {:reply, TestGenServers.Repo.get(TestGenServers.Model.Product, id), state} 
    end 

end 

測試模塊：

defmodule TestGenServers.TestMyServer do 
    use TestGenServers.DataCase 

    setup do 
    product = Repo.insert!(%TestGenServers.Model.Product{name: "widget123"}) 
    %{product_id: product.id} 
    end 

    test "talk to gen server", %{product_id: id} do 
    assert %{id: ^id, name: "widget123"} = GenServer.call(TestGenServers.MyServer, {:get_product, id}) 
    end 
end 

DataCase模塊

defmodule TestGenServers.DataCase do 
    use ExUnit.CaseTemplate 

    using do 
    quote do 
     alias TestGenServers.Repo 
     import TestGenServers.DataCase 
    end 
    end 

    setup tags do 
    :ok = Ecto.Adapters.SQL.Sandbox.checkout(TestGenServers.Repo) 
    unless tags[:async] do 
     Ecto.Adapters.SQL.Sandbox.mode(TestGenServers.Repo, {:shared, self()}) 
    end 
    :ok 
    end 
end 

test_helper：

ExUnit.start() 

Ecto.Adapters.SQL.Sandbox.mode(TestGenServers.Repo, :manual)