選擇範圍內的形狀。奇怪的看似隨機的結果？

Question

我試圖選擇一個範圍內的形狀，但代碼的結果並不完全符合我的預期。它隨機選擇比預期更多的形狀（不在範圍內）。

Public Sub ShapeSelection() 
Dim Sh As Shape 
Dim selectedOne As Boolean 
On Error Resume Next 

With ActiveSheet 
    For Each Sh In .Shapes 
     If Not Application.Intersect(Sh.TopLeftCell, .Range(Selection.Address)) Is Nothing Then 
      If selectedOne = False Then 
       Sh.Select 
       selectedOne = True 
      Else 
       Sh.Select (False) 
      End If 
     End If 
    Next Sh 
End With 
End Sub 

Answer 1

奇怪的行爲由「Selection.Address」

在你的循環，當第一個形狀被發現引起的，你從範圍C3改變當前的選擇，讓我們說，到第一形狀

下次通過循環它試圖比較（相交）TopLeftCell的地址與形狀對象的地址：形狀對象本身沒有地址（其TopLeftCell有一個）

但是你去了關於它很長的路要走：你不需要使用相交。代碼波紋管工作如你所期望：

Option Explicit 

Public Sub ShapeSelection() 

    Dim Sh As Shape 
    Dim sRng As Range 

    With ActiveSheet 
     Set sRng = Selection 
     For Each Sh In .Shapes 
      If Sh.TopLeftCell.Address = sRng.Address Then 
       Sh.Select 
       Exit For 
      End If 
     Next Sh 
    End With 
End Sub 

---

編輯：我剛纔注意到你前面的問題：How to select multiple shapes based on range?

交點所需要完成這一要求，但你仍然需要保留對所選單元格的引用：

Option Explicit 

Public Sub ShapeSelection() 

    Dim Sh As Shape 
    Dim sRng As Range 

    With ActiveSheet 
     If TypeName(Selection) = "Range" Then 
      Set sRng = Selection 
      If sRng.CountLarge = 1 Then 
       For Each Sh In .Shapes 
        Sh.Select False 
       Next Sh 
      Else 
       For Each Sh In .Shapes 
        If Not Application.Intersect(Sh.TopLeftCell, .Range(sRng.Address)) Is Nothing Then 
         Sh.Select False 
        End If 
       Next Sh 
      End If 
     End If 
    End With 
End Sub