保存狀態的StringList

Question

在我的應用程序中的TStringList節省一些編輯值與下面的代碼：

procedure TForm1.Button3Click(Sender: TObject); 
var 
    F: TStringList; 
begin 
    SaveDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if SaveDialog1.Execute then 
    begin 
     F := TStringList.Create; 
     with F do 
     begin 
      Add(label7.Caption); 
      Add(label21.Caption); 
      SaveToFile(Savedialog1.Filename); 
      Free; 
     end; 
    end; 
end; 

我想也保存在這個TStringList中Tradiobutton狀態。 你能幫我嗎？ 問候

Answer 1

製作的回答只是爲了顯示正確格式化形式的代碼示例

閱讀：

• try/finally模式 - http://docwiki.embarcadero.com/RADStudio/XE2/en/Writing_a_Finally_Block_(Delphi)
• TIniFile類boolean值 - http://docwiki.embarcadero.com/Libraries/XE2/en/System.IniFiles.TCustomIniFile.WriteBool - 作爲一個有點過時的功能有限，但是文本格式非常簡單。

所以，你的代碼將成爲像

const ini_def_sect = 'Default Section'; 

procedure TForm1.Button3Click(Sender: TObject); 
var 
    F: TCustomIniFile; 
begin 
    SaveDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if SaveDialog1.Execute then 
    begin 
     F := TIniFile.Create(SaveDialog1.Filename); 
     try 
      F.WriteString(ini_def_sect, label7.Name, label7.Caption); 
      F.WriteString(ini_def_sect, label21.Name, label21.Caption); 
      F.WriteBool(ini_def_sect, radiobutton1.Name, radiobutton1.Checked); 
      F.UpdateFile; 
     finally 
      F.Destroy; 
     end; 
    end; 
end; 

或者在VCL與基於風格（很多人不喜歡，他們不喜歡帕斯卡爾with語句）

const ini_def_sect = 'Default Section'; 

procedure TForm1.Button3Click(Sender: TObject); 
begin 
    SaveDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if SaveDialog1.Execute then 
    begin 
     with TIniFile.Create(Savedialog1.Filename) do 
     try 
      WriteString(ini_def_sect, label7.Name, label7.Caption); 
      WriteString(ini_def_sect, label21.Name, label21.Caption); 
      WriteBool(ini_def_sect, radiobutton1.Name, radiobutton1.Checked); 
      UpdateFile; 
     finally 
      Destroy; 
     end; 
    end; 
end; 

而且你真的真的應該給你的變量（包括標籤，表單，單選按鈕等）合理的名稱，而你仍然可以記住一些有關這些都意味着什麼。相信我 - 一個月或兩個月，你會忘記。

PS：讀取結構文件就應該像這樣

procedure TMainForm.btnOpenClick(Sender: TObject); 
begin 
    OpenDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if OpenDialog1.Execute then 
    begin 
     with TIniFile.Create(OpenDialog1.Filename) do 
     try 
      label7.Caption := ReadString(ini_def_sect, label7.Name, ''); 
      label21.Caption := ReadString(ini_def_sect, label21.Name, ''); 
      radiobutton1.Checked := ReadBool(ini_def_sect, radiobutton1.Name, False); 
     finally 
      Destroy; 
     end; 
    end; 
end;