XSLT處理文本，分散在各個節點

Question

輸入文件如下：

<?xml version="1.0" encoding="UTF-8"?> 
<!-- lower UPPER case --> 
<document> 
    <rubbish> rubbish </rubbish> 
    <span class='lower'> 
    lower 
    <span class='upper'> upper </span> 
    case 
    </span> 
</document> 

通緝輸出：

lower UPPER case 

我知道如何讓包括在外span與value-of文本，但是這也 包括字符串"upper"不變，這不是我想要的。我不知道 如何操作span內部的文字並將其插入 中間的其他文字。

失敗的嘗試：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       version="1.0"> 
    <xsl:output method="text" indent="no"/> 
    <xsl:template match="/"> 
    <xsl:for-each select="//span[@class = 'lower']"> 
     <xsl:if test="span/@class = 'upper'"> 
     <xsl:text>do something</xsl:text> <!--TO DO --> 
     </xsl:if> 
     <xsl:value-of select="."/> 
    </xsl:for-each> 
    </xsl:template> 
</xsl:stylesheet> 

Answer 1

這裏需要採取一種遞歸方法，例如：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema"> 
<xsl:output method="text" encoding="UTF-8"/> 

<xsl:template match="text()[parent::span]"> 
    <xsl:choose> 
     <xsl:when test="../@class='upper'"> 
      <xsl:value-of select="translate(., 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')" /> 
     </xsl:when> 
     <xsl:otherwise> 
      <xsl:value-of select="." /> 
     </xsl:otherwise> 
    </xsl:choose> 
</xsl:template> 

<xsl:template match="text()"/> 

</xsl:stylesheet> 

要理解這是如何工作的，在讀了內置模板規則：http://www.w3.org/TR/xslt/#built-in-rule

Answer 2

以下方法消除<choose>並將問題完全推向匹配表達式：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet 
    version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" /> 

    <xsl:template match="text()"/> 

    <xsl:template match="text()[parent::span[@class = 'upper']]"> 
    <xsl:value-of select="translate(., 'abcdefghijklmnopqrstuvwxyz', 'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/> 
    </xsl:template> 

    <xsl:template match="text()[parent::span[@class = 'lower']]"> 
    <xsl:value-of select="translate(., 'ABCDEFGHIJKLMNOPQRSTUVWXYZ', 'abcdefghijklmnopqrstuvwxyz')"/> 
    </xsl:template> 

</xsl:stylesheet>