在SAS

Question

特殊類型的總結，我有以下數據：

我想知道有多少獨特的客戶，每年每月都有一定的產品。 從和到列是產品何時「有效」，並且如果客戶更改其尺寸，顏色或產品，或者一年過去了，則會獲得新的一排。我不關心顏色或尺寸，只關心產品的類型。我知道有些方法可以做到這一點，但它們非常乏味。

例如，在2014年第1個月，我想知道有多少獨特的客戶，有產品1，產品2或產品3

Year Month no product 1 no product 2 no product 3 
2014 1   1    0     0 

（只有傑拉德是「有效」的那個時候，他只有產品1）

我想有一個這樣的列表所有「有效」年和月。

編輯： 數據：

name from   to  colour size product 
Jenny 15JAN2015 15JAN2016' red  small 1 
Jenny 15JAN2016' 15JAN2017' green big  1 
Jenny 15JAN2017' 15JAN2018' blue big  3 
Bob  05APR2014 05APR2015 blue small 2 
Bob  05APR2015 05APR2016 green small 2 
Gerald 23MAY2013 23DEC2013 red  small 2 
Gerald 23DEC2013 23MAY2014 yellow big  1 
Gerald 23MAY2014 04SEP2014 green big  1 
Gerald 04SEP2014 25DEC2014 red  small 2 
Hope 23MAY2014 04SEP2014 red  small 1 
Hope 04SEP2014 25DEC2014 red  small 1 
Siri 15JAN2016' 15JAN2017' red  small 1 

Answer 1

如果展開的原始數據，讓你有每個月客戶持有產品爲一排，那麼它是做一個頻率的簡單的事情計數並轉換結果以獲得所需的格式。我的答案唯一的區別是我已將年份和月份顯示爲1列，因爲它使循環更容易。

/* source data */ 
data have; 
input name $ from_dt :date9. to_dt :date9. colour $ size $ product; 
format from_dt to_dt date9.; 
datalines; 
Jenny 15JAN2015 15JAN2016 red small 1 
Jenny 15JAN2016' 15JAN2017' green big 1 
Jenny 15JAN2017' 15JAN2018' blue big 3 
Bob 05APR2014 05APR2015 blue small 2 
Bob 05APR2015 05APR2016 green small 2 
Gerald 23MAY2013 23DEC2013 red small 2 
Gerald 23DEC2013 23MAY2014 yellow big 1 
Gerald 23MAY2014 04SEP2014 green big 1 
Gerald 04SEP2014 25DEC2014 red small 2 
Hope 23MAY2014 04SEP2014 red small 1 
Hope 04SEP2014 25DEC2014 red small 1 
Siri 15JAN2016' 15JAN2017' red small 1 
; 
run; 

/* expand data to have a row for every month */ 
data temp1; 
format mthyr yymm8.; 
set have; 
do i = 0 to intck('month',intnx('month',from_dt,0),intnx('month',to_dt,0)); 
mthyr = intnx('month',from_dt,i); 
output; 
end; 
run; 

/* count frequencies of products per month */ 
proc freq data=temp1 noprint; 
table mthyr*product/sparse out=temp2; 
run; 

/* transpose data */ 
proc transpose data=temp2 out=want (drop=_:) prefix=product; 
by mthyr; 
id product; 
var count; 
run;